File Coverage

blib/lib/Gtk2/Ex/Spinner/CellRenderer.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package Gtk2::Ex::Spinner::CellRenderer;
use 5.008;
use strict;
use warnings;
use Gtk2;

our $VERSION = 5.1;

use constant DEBUG => 0;

use Glib::Object::Subclass
  'Gtk2::CellRendererText';

# gtk_cell_renderer_start_editing()
#
# SUPER::START_EDITING of Gtk2::CellRendererText is no good for the
# Gtk2::Entry creation because it sets that widget to stop editing on losing
# keyboard focus, which includes the switch away to the
# Spinner::PopupEntry window, the effect being to immediately stop
# editing when that window pops up.
#
sub START_EDITING {
  my ($self, $event, $view, $pathstr, $back_rect, $cell_rect, $flags) = @_;
  if (DEBUG) { print "Renderer START_EDITING '$pathstr'\n";
               print "  back ",$back_rect->x,",",$back_rect->y,
                 " ",$back_rect->width,"x",$back_rect->width,
                   "  cell ",$cell_rect->x,",",$cell_rect->y,
                     " ",$cell_rect->width,"x",$cell_rect->width,"\n";
             }
  $self->{'pathstr'} = $pathstr;

  # no frame and copy 'xalign' across, the same as CellRendererText does
  require Gtk2::Ex::Spinner::EntryWithCancel;
  my $entry = Gtk2::Ex::Spinner::EntryWithCancel->new
    (has_frame => 0,
     xalign => $self->get('xalign'));
  if (DEBUG) { print "  edit with $entry\n"; }

  {
    # This is a hack for Gtk2-Perl 1.210 and earlier ensuring
    # gtk2perl_cell_renderer_start_editing() doesn't see $entry with a
    # refcount of 1, since it would increment that as a protection against
    # premature destruction -- but then never decrement.  If the refcount is
    # 2 it leaves it alone.
    Glib::Idle->add (sub { 0 }, # Glib::SOURCE_REMOVE
                     $entry);
  }

  require Gtk2::Ex::Spinner::PopupForEntry;
  Gtk2::Ex::Spinner::PopupForEntry->new (entry => $entry);

  my $value = $self->get('text');
  $entry->set_text (defined $value ? $value : '');
  $entry->select_region (0, -1);

  my $ref_weak_self = \$self;
  require Scalar::Util;
  Scalar::Util::weaken ($ref_weak_self);
  $entry->signal_connect (editing_done => \&_do_entry_editing_done,
                          $ref_weak_self);

  if (DEBUG) {
    $entry->signal_connect (destroy => sub {
                              print "editable: destroy\n";
                            });
    $entry->signal_connect (focus_out_event => sub {
                              print "editable: focus_out_event\n";
                              return 0; # Gtk2::EVENT_PROPAGATE
                            });
  }
  $entry->show;
  return $entry;
}

# 'editing-done' handler on the Gtk2::Ex::Spinner::EntryWithCancel
#
sub _do_entry_editing_done {
  my ($entry, $ref_weak_self) = @_;
  my $self = $$ref_weak_self || return;
  if (DEBUG) { print "Spinner::CellRenderer _do_entry_editing_done,",
                 " cancelled ",($entry->get('editing_cancelled')?"yes":"no"),
                   "\n"; }

  my $cancelled = $entry->get('editing_cancelled');
  $self->stop_editing ($cancelled);
  if (! $cancelled) {
    $self->signal_emit ('edited', $self->{'pathstr'}, $entry->get_text);
  }
}

1;
__END__