File Coverage

lib/Gtk2/Ex/MindMapView/Border/RoundedRect.pm

Criterion	Covered	Total	%
statement	13	15	86.6
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	18	20	90.0

package Gtk2::Ex::MindMapView::Border::RoundedRect;

our $VERSION = '0.000001';

use warnings;
use strict;
use Carp;

use List::Util;

use Gnome2::Canvas;

use Gtk2::Ex::MindMapView::ArgUtils;

use base 'Gtk2::Ex::MindMapView::Border';

sub new
{
    my $class = shift(@_);

    my $self = $class->SUPER::new(@_);

    my %attributes = @_;

    args_valid(\%attributes, qw(group content x y width height radius width_pixels
				padding_pixels fill_color_gdk outline_color_gdk));

    arg_default($self, "radius", 10);

    arg_default($self, "fill_color_gdk", Gtk2::Gdk::Color->parse('white'));

    arg_default($self, "outline_color_gdk", Gtk2::Gdk::Color->parse('gray'));

    $self->{content}->set(anchor=>'north-west');

    my ($top, $left, $bottom, $right) = $self->border_insets();

    $self->{width}  = $self->{content}->get('width') + ($left + $right);

    $self->{height} = $self->{content}->get('height') + ($top + $bottom);

    $self->{border} = $self->border_get_image();

    return $self;
}


# $border->border_get_image();

sub border_get_image
{
    my $self = shift(@_);

    my $border = Gnome2::Canvas::Item->new($self->{group}, 'Gnome2::Canvas::Shape',
					   'fill-color-gdk'=>$self->{fill_color_gdk},
					   'outline-color-gdk'=>$self->{outline_color_gdk});

    $border->set_path_def(_rounded_rect($self));

    return $border;
}


# $border->border_set_x($value);

sub border_set_x
{
    my ($self, $value) = @_;

    $self->{border}->set_path_def(_rounded_rect($self));

    $self->{border}->request_update();
}


# $border->border_set_y($value);

sub border_set_y
{
    my ($self, $value) = @_;

    $self->{border}->set_path_def(_rounded_rect($self));

    $self->{border}->request_update();
}


# $border->border_set_width($value);

sub border_set_width
{
    my ($self, $value) = @_;

    $self->{border}->set_path_def(_rounded_rect($self));

    $self->{border}->request_update();
}


# $border->border_set_height($value);

sub border_set_height
{
    my ($self, $value) = @_;

    $self->{border}->set_path_def(_rounded_rect($self));

    $self->{border}->request_update();
}


# $border->border_set_param($name, $value);

sub border_set_param
{
    my ($self, $name, $value) = @_;

    $self->{border}->set($name=>$value);
}


sub _bezier
{
    my ($self, $corner, $x, $y) = @_;

    my $r = _radius($self);

    if ($corner eq 'upper_left')
    {
	return ($x,$y+$r, $x,$y+($r/2), $x+($r/2),$y, $x+$r, $y);
    }

    if ($corner eq 'upper_right')
    {
	return ($x-$r,$y, $x-($r/2),$y, $x,$y+($r/2), $x, $y+$r);
    }

    if ($corner eq 'lower_right')
    {
	return ($x,$y-$r, $x,$y-($r/2), $x-($r/2),$y, $x-$r, $y);
    }

    if ($corner eq 'lower_left')
    {
	return ($x+$r,$y, $x+($r/2),$y, $x,$y-($r/2), $x, $y-$r);
    }

    croak "Invalid corner argument: $corner\n";
}


sub _radius
{
    my $self = shift(@_);

    my $max_radius = List::Util::min($self->{width}, $self->{height}) * 3 / 8;

    return List::Util::max(0, List::Util::min($self->{radius}, $max_radius));
}


sub _rounded_rect
{
    my $self = shift(@_);

    my $x1 = $self->{x};

    my $y1 = $self->{y};

    my $x2 = $self->{x} + $self->{width};

    my $y2 = $self->{y} + $self->{height};

#    print "_rounded_rect, x: $self->{x}  y: $self->{y}  width: $self->{width}  height: $self->{height}\n";

    my @p = ();

    push @p, _bezier($self, 'upper_left',  $x1, $y1);

    push @p, _bezier($self, 'upper_right', $x2, $y1);

    push @p, _bezier($self, 'lower_right', $x2, $y2);

    push @p, _bezier($self, 'lower_left',  $x1, $y2);

    my $pathdef = Gnome2::Canvas::PathDef->new();

    $pathdef->moveto  ($p[0],  $p[1]);

    $pathdef->curveto ($p[2],  $p[3],  $p[4],  $p[5],  $p[6],  $p[7]);

    $pathdef->lineto  ($p[8],  $p[9]);

    $pathdef->curveto ($p[10], $p[11], $p[12], $p[13], $p[14], $p[15]);

    $pathdef->lineto  ($p[16], $p[17]);

    $pathdef->curveto ($p[18], $p[19], $p[20], $p[21], $p[22], $p[23]);

    $pathdef->lineto  ($p[24], $p[25]);

    $pathdef->curveto ($p[26], $p[27], $p[28], $p[29], $p[30], $p[31]);

    $pathdef->lineto  ($p[0],  $p[1]);

    # Close the path so that 'fill-color' will work.
    $pathdef->closepath_current;

    return $pathdef;
}



1; # Magic true value required at end of module
__END__