File Coverage

blib/lib/Growl/Any.pm

Criterion	Covered	Total	%
statement	13	13	100.0
branch	1	2	50.0
condition			n/a
subroutine	5	5	100.0
pod	1	1	100.0
total	20	21	95.2

package Growl::Any;

use 5.008_001;
use strict;
use warnings;
use constant _DEBUG => $ENV{GROWL_ANY_DEBUG} ? 1 : 0;

our $VERSION = '0.09';

my $backend;

# already loaded?
foreach my $module(keys %INC) {
    if($module =~ m{\A Growl/Any/ }xms && $module !~ m{ /Base.pm \z}xms) {
        $backend = $module;

        print STDERR "$backend loaded.\n" if _DEBUG;
    }
}

# try to find the backend
if(!$backend) {
    my @backends = qw(
        MacGrowl
        CocoaGrowl
        GrowlNotifySend
        DesktopNotify
        GrowlGNTP
        NetGrowlClient
        NetGrowl
        Win32MSAgent

        Null
        IOHandle
    );
    if (my $default_backend = $ENV{GROWL_ANY_DEFAULT_BACKEND}) {
        unshift @backends, $default_backend;
    }

    foreach my $b(@backends) {
        my $file = "Growl/Any/$b.pm";
        print STDERR "try to load $file ... " if _DEBUG;
        if(eval { require $file }) {
            $backend = $file;
            print STDERR "ok.\n" if _DEBUG;
            last;
        }
        else {
            print STDERR "not ok.\n" if _DEBUG;
        }
    }
}

$backend =~ s{/}{::}xmsg;
$backend =~ s/\.pm \z//xms;

our @ISA = ($backend);

sub backend { $backend }

1;
__END__