File Coverage

blib/lib/Graph/Easy/Parser/Graph6.pm

Criterion	Covered	Total	%
statement	45	45	100.0
branch	7	8	87.5
condition	5	5	100.0
subroutine	14	14	100.0
pod	2	2	100.0
total	73	74	98.6

# Copyright 2015, 2016, 2017 Kevin Ryde
#
# This file is part of Graph-Graph6.
#
# Graph-Graph6 is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 3, or (at your option) any later
# version.
#
# Graph-Graph6 is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
# more details.
#
# You should have received a copy of the GNU General Public License along
# with Graph-Graph6.  If not, see .

package Graph::Easy::Parser::Graph6;
use 5.006;  # Graph::Easy is 5.008 anyway
use strict;
use warnings;
use Graph::Graph6;
use Graph::Easy::Parser;

our $VERSION = 8;
our @ISA = ('Graph::Easy::Parser');

# uncomment this to run the ### lines
# use Smart::Comments;


sub _default_vertex_name_func {
  my ($n, $num_vertices) = @_;
  return sprintf '%0*d', length($num_vertices-1), $n;
}
sub _init {
  my ($self, $args) = @_;

  # this undocumented yet ...
  $self->{'vertex_name_func'} = delete $args->{'vertex_name_func'}
    || \&_default_vertex_name_func;

  return $self->SUPER::_init($args);
}

sub from_file {
  my ($self, $filename_or_fh) = @_;
  return _read_graph6($self,
                     (ref $filename_or_fh
                      ? (fh       => $filename_or_fh)
                      : (filename => $filename_or_fh)));
}
sub from_text {
  my ($self, $str) = @_;
  return _read_graph6($self, str => $str);
}

sub _read_graph6 {
  my ($self, @options) = @_;

  if (! ref $self) { $self = $self->new; } # class method
  $self->reset;

  my $graph = $self->{'_graph'};
  my $num_vertices;
  my $vertex_name_func = $self->{'vertex_name_func'};

  my $ret = Graph::Graph6::read_graph
    (@options,
     format_func => sub {
       my ($format) = @_;
       unless ($format eq 'digraph6') {
         $graph->set_attribute (type => 'undirected');
       }
     },
     num_vertices_func => sub {
       my ($n) = @_;
       ### num_vertices_func(): $n
       $num_vertices = $n;
       foreach my $i (0 .. $n-1) {
         my $name = $vertex_name_func->($i,$num_vertices);
         $graph->add_node($name);
       }
     },
     edge_func => sub {
       my ($from, $to) = @_;
       ### edge_func() ...
       ### $from
       ### $to
       $graph->add_edge($vertex_name_func->($from,$num_vertices),
                        $vertex_name_func->($to,  $num_vertices));
     },
     error_func => sub {
       $self->error(@_);
     });
  ### $ret

  if (defined $ret && $ret == 0) {
    return undef;  # EOF
  }

  # When fatal_errors is false Graph::Easy::Parser returns a partial graph,
  # though its docs suggest undef.  Try to follow its behaviour.
  return $graph;
}

1;
__END__