File Coverage

blib/lib/Graph/Easy/As_graph6.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	4	4	100.0
condition	8	8	100.0
subroutine	7	7	100.0
pod	0	1	0.0
total	50	51	98.0

# Copyright 2015, 2016, 2017 Kevin Ryde
#
# This file is part of Graph-Graph6.
#
# Graph-Graph6 is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 3, or (at your option) any later
# version.
#
# Graph-Graph6 is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
# more details.
#
# You should have received a copy of the GNU General Public License along
# with Graph-Graph6.  If not, see .

package Graph::Easy::As_graph6;
use 5.006;  # Graph::Easy is 5.008 anyway
use strict;
use warnings;
use Graph::Graph6;

# uncomment this to run the ### lines
# use Smart::Comments;

our $VERSION = 7;


package Graph::Easy;

# In Graph::Easy 0.75 and 0.76, an undirected graph has_edge($v1,$v2) is
# true only of $v1,$v2 passed in the original edge order, not as $v2,$v1.
# That's probably a bug.
#
# To get the right result, _has_edge_either() is always used for undirected
# graphs.
#
#     output       $graph        method
#     ------       ------        ------
#     graph6       undirected    _has_edge_either() due to has_edge()
#     graph6       directed      _has_edge_either() write either way
#     digraph6     undirected    _has_edge_either() to write both ways
#     digraph6     directed      has_edge()
#
# For graph6 output, maybe some sort of Graph::Easy ->has_neighbour() could
# answer $v1,$v2 either way round for both directed and undirected graphs.
# Name has_neighbour() would correspond to Graph.pm neighbours(), so
# has_neighbour() would be whether a given $v2 is among the neighbours of
# $v1.  (neighbours() are all adjacent vertices, for edges in either
# direction.)

sub _has_edge_either {
  my ($graph, $from, $to) = @_;
  return $graph->has_edge($from,$to) || $graph->has_edge($to,$from);
}

sub as_graph6 {
  my ($graph, %options) = @_;
  ### Graph-Easy as_graph6() ...

  my @vertices = $graph->sorted_nodes('name');
  my $format = $options{'format'} || 'graph6';
  ### $format

  my @edge_options;
  if ($format eq 'sparse6') {
    my @edges = $graph->edges;  # Graph::Easy::Edge objects
    my %name_to_num = map { $vertices[$_]->name => $_ } 0 .. $#vertices;
    @edges = map { [map{$name_to_num{$_->name}} $_->nodes] } @edges;
    ### @edges
    @edge_options = (edge_aref => \@edges)

  } else {
    my $has_edge_method = ($graph->is_directed && $format eq 'digraph6'
                           ? 'has_edge'
                           : \&_has_edge_either);
    @edge_options
      = (edge_predicate
         => sub {
           my ($from, $to) = @_;
           return $graph->$has_edge_method($vertices[$from], $vertices[$to]);
         });
  }

  Graph::Graph6::write_graph
      (format         => $format,
       header         => $options{'header'},
       str_ref        => \my $str,
       num_vertices   => scalar(@vertices),
       @edge_options);
  ### $str
  return $str;
}

1;
__END__