File Coverage

blib/lib/Gnuplot/Builder/Template.pm

Criterion	Covered	Total	%
statement	25	25	100.0
branch	2	2	100.0
condition			n/a
subroutine	9	9	100.0
pod	2	2	100.0
total	38	38	100.0

package Gnuplot::Builder::Template;
use strict;
use warnings;
use Exporter 5.57 qw(import);
use Carp;
use Gnuplot::Builder::JoinDict;

our @EXPORT_OK = qw(gusing gevery);

sub _create_hyphen_validator {
    my ($allowed_keys_arrayref) = @_;
    my %allowed_keys = map { $_ => 1 } @$allowed_keys_arrayref;
    return sub {
        my ($dict) = @_;
        foreach my $hyphen_key (grep { substr($_, 0, 1) eq "-" } $dict->get_all_keys) {
            croak "Unknown key: $hyphen_key" if !$allowed_keys{$hyphen_key};
        }
    };
}

our $USING;

{
    my @using_keys = grep { substr($_, 0, 1) eq "-" }
        qw(
    USE CASES       | KEYS
    ================+==============================================
                    | -x -y
    filledcurves    | -y1 -y2
                    | -z
    polar           | -t
    image           | -value
    smooth kdensity | -weight -bandwidth
    rgbalpha        | -r -g -b -a
    labels          | -string -label
    vectors         | -xdelta -ydelta -zdelta
    xerrorbars      | -xlow -xhigh
    yerrorbars      | -ylow -yhigh
    financebars     | -date -open -low -high -close
    candlesticks    | -box_min -whisker_min -whisker_high -box_high
    boxes           | -x_width
    boxplot         | -boxplot_factor
    circles         | -radius -start_angle -end_angle
    ellipses        | -major_diam -minor_diam -angle
    variable style  | -pointsize -arrowstyle -linecolor
      );

    $USING = Gnuplot::Builder::JoinDict->new(
        separator => ":",
        content => [map { $_ => undef } @using_keys],
        validator => _create_hyphen_validator(\@using_keys),
    );
}

our $EVERY;

{
    my @every_keys =
        qw(
    -point_incr
    -block_incr
    -start_point
    -start_block
    -end_point
    -end_block
      );
    $EVERY = Gnuplot::Builder::JoinDict->new(
        separator => ":",
        content => [$every_keys[0] => 1, map { $_ => undef } @every_keys[1 .. $#every_keys]],
        validator => _create_hyphen_validator(\@every_keys),
        filter => sub {
            my ($dict) = @_;
            my @values = $dict->get_all_values;
            my ($first_def_index, $last_def_index);
            foreach my $front_i (0 .. $#values) {
                my $rear_i = $#values - $front_i;
                if(!defined($first_def_index) && defined($values[$front_i])) {
                    $first_def_index = $front_i;
                }
                if(!defined($last_def_index) && defined($values[$rear_i])) {
                    $last_def_index = $rear_i;
                }
                if(defined($first_def_index) && defined($last_def_index)) {
                    last;
                }
            }
            return () if !defined($first_def_index) || !defined($last_def_index);
            return map {
                defined($_) ? $_ : ""
            } @values[$first_def_index .. $last_def_index];
        }
    );
}

sub gusing {
    return $USING->set(@_);
}

sub gevery {
    return $EVERY->set(@_);
}

1;
__END__