File Coverage

blib/lib/Git/Wrapper/Plus/Tags.pm

Criterion	Covered	Total	%
statement	50	52	96.1
branch	5	8	62.5
condition			n/a
subroutine	13	13	100.0
pod	4	4	100.0
total	72	77	93.5

use 5.006;    # our
use strict;
use warnings;

package Git::Wrapper::Plus::Tags;

our $VERSION = '0.004011';

# ABSTRACT: Extract all tags from a repository

our $AUTHORITY = 'cpan:KENTNL'; # AUTHORITY













use Moo qw( has );








































has 'git' => ( is => ro =>, required => 1 );







has 'refs' => ( is => ro =>, lazy => 1, builder => 1 );

sub _build_refs {
  my ($self) = @_;
  require Git::Wrapper::Plus::Refs;
  return Git::Wrapper::Plus::Refs->new( git => $self->git );
}

sub _to_tag {
  my ( undef, $ref ) = @_;
  require Git::Wrapper::Plus::Ref::Tag;
  return Git::Wrapper::Plus::Ref::Tag->new_from_Ref($ref);
}

sub _to_tags {
  my ( $self, @refs ) = @_;
  return map { $self->_to_tag($_) } @refs;
}

# There's 2 types of results that come back from git ls-remote
#
# tags, and heavy tags ( usually annotations )
#
# puretags look like
#
#    abffab foo         # pointer to the commit
#
# While heavy tags come in pairs
#
#   fabfab  foo         # heavy tag pointer
#   abffab  foo^{}      # pointer to the actual commit
#
# However, we don't really care about the second half of the latter kind.
#
sub _grep_commit_pointers {
  my ( undef, @refs ) = @_;
  my (@out);
  for my $ref (@refs) {
    next if $ref->name =~ /[^][{][}]\z/msx;
    push @out, $ref;
  }
  return @out;
}











sub tags {
  my ($self) = @_;
  return $self->get_tag(q[**]);
}

























sub get_tag {
  my ( $self, $name ) = @_;
  return $self->_to_tags( $self->_grep_commit_pointers( $self->refs->get_ref( 'refs/tags/' . $name ) ) );
}













sub tag_sha1_map {
  my ($self) = @_;

  my %hash;
  for my $tag ( $self->tags ) {
    my $sha_one = $tag->sha1;
    if ( not exists $hash{$sha_one} ) {
      $hash{$sha_one} = [];
    }
    push @{ $hash{$sha_one} }, $tag;
  }
  return \%hash;
}













sub tags_for_rev {
  my ( $self, $rev ) = @_;
  my (@shas) = $self->git->rev_parse($rev);
  if ( scalar @shas != 1 ) {
    require Carp;
    Carp::croak("Could not resolve a SHA1 from rev $rev");
  }
  my ($sha) = shift @shas;
  my $map = $self->tag_sha1_map;
  return unless exists $map->{$sha};
  return @{ $map->{$sha} };
}

no Moo;

1;

__END__