File Coverage

blib/lib/Git/Repository/FileHistory.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package Git::Repository::FileHistory;
use strict;
use warnings;
use 5.008001;
our $VERSION = '0.05';

use Git::Repository::Log::Iterator;

sub new {
    my ($class, $repo, @files) = @_;

    my $args;
       $args = pop @files if ref $files[-1] eq 'HASH';

    my @cmd = ('--', @files);
    unshift @cmd, $args->{branch} if $args->{branch};

    my $iter = Git::Repository::Log::Iterator->new($repo, @cmd);
    my @logs;
    while ( my $log = $iter->next ){
        push @logs, $log;
    }

    bless {
        file_name => @files == 1 ? $files[0] : \@files,
        logs      => \@logs,
    }, $class;
}

sub file_name { shift->{file_name} }

sub logs {
    my $logs = shift->{logs};
    wantarray ? @$logs : $logs;
}

sub last_log  { shift->logs->[0]  }
sub first_log { shift->logs->[-1] }

sub created_at {
    my $first = shift->first_log;
    $first && $first->author_gmtime;
}

sub last_modified_at {
    my $last = shift->last_log;
    $last && $last->author_gmtime;
}
{
    no warnings 'once';
    *updated_at = *last_modified_at;
}

sub created_by {
    my $first = shift->first_log;
    $first && $first->author_name;
}

sub last_modified_by {
    my $last = shift->last_log;
    $last && $last->author_name;
}

1;
__END__