File Coverage

lib/Git/Lint.pm

Criterion	Covered	Total	%
statement	22	54	40.7
branch	0	14	0.0
condition	0	3	0.0
subroutine	7	10	70.0
pod	3	3	100.0
total	32	84	38.1

package Git::Lint;

use strict;
use warnings;

use Git::Lint::Config;
use Try::Tiny;
use Module::Loader;

our $VERSION = '0.016';

my $config;

sub new {
    my $class = shift;
    my $self  = { issues => undef };

    bless $self, $class;

    $config = Git::Lint::Config->load();

    return $self;
}

sub config {
    my $self = shift;
    return $config;
}

sub run {
    my $self = shift;
    my $opt  = shift;

    foreach my $required (qw{profile check}) {
        die "git-lint: $required is required\n"
            unless defined $opt->{$required};
    }

    if ( $opt->{check} ne 'message' && $opt->{check} ne 'commit' ) {
        die "git-lint: check must be either message or commit\n";
    }

    if ( $opt->{check} eq 'message' ) {
        die "git-lint: file is required if check is message\n"
            unless defined $opt->{file};
    }

    die 'git-lint: profile ' . $opt->{profile} . ' was not found' . "\n"
        unless exists $self->config->{profiles}{ $opt->{check} }{ $opt->{profile} };

    my $check = lc $opt->{check};
    $check = ucfirst $check;

    my $loader = Module::Loader->new;

    my @issues;
    foreach my $module ( @{ $self->config->{profiles}{ $opt->{check} }{ $opt->{profile} } } ) {
        my $class = q{Git::Lint::Check::} . $check . q{::} . $module;
        try {
            $loader->load($class);
        }
        catch {
            my $exception = $_;
            die "git-lint: $exception\n";
        };
        my $plugin = $class->new();

        # TODO: this would be better to be named the same method
        my $input = ( $opt->{check} eq 'commit' ? $class->diff() : $class->message( file => $opt->{file} ) );

        # ensure the plugins don't manipulate the original input
        my @lines = @{$input};
        push @issues, $plugin->check( \@lines );
    }

    foreach my $issue (@issues) {
        if ( $opt->{check} eq 'commit' ) {
            push @{ $self->{issues}{ $issue->{filename} } }, $issue->{message};
        }
        else {
            push @{ $self->{issues} }, $issue->{message};
        }
    }

    return;
}

1;

__END__