File Coverage

lib/Git/Lint/Config.pm

Criterion	Covered	Total	%
statement	47	53	88.6
branch	5	8	62.5
condition	1	3	33.3
subroutine	9	10	90.0
pod	2	2	100.0
total	64	76	84.2

package Git::Lint::Config;

use strict;
use warnings;

use Module::Loader;
use List::MoreUtils ();
use Git::Lint::Command;

our $VERSION = '0.014';

sub load {
    my $class = shift;
    my $self  = { profiles => undef };

    $self->{profiles}{commit}{default}  = [];
    $self->{profiles}{message}{default} = [];

    # all check modules are added to the default profile
    my $loader        = Module::Loader->new;
    my $namespace     = 'Git::Lint::Check::Commit';
    my @commit_checks = List::MoreUtils::apply {s/$namespace\:\://g} $loader->find_modules( $namespace, { max_depth => 1 } );

    if (@commit_checks) {
        $self->{profiles}{commit}{default} = \@commit_checks;
    }

    $namespace = 'Git::Lint::Check::Message';
    my @message_checks = List::MoreUtils::apply {s/$namespace\:\://g} $loader->find_modules( $namespace, { max_depth => 1 } );

    if (@message_checks) {
        $self->{profiles}{message}{default} = \@message_checks;
    }

    bless $self, $class;

    my $user_config = $self->user_config();

    # user defined profiles override internally defined profiles
    foreach my $cat ( keys %{$user_config} ) {
        foreach my $check ( keys %{ $user_config->{$cat} } ) {
            foreach my $profile ( keys %{ $user_config->{$cat}{$check} } ) {
                $self->{$cat}{$check}{$profile} = $user_config->{$cat}{$check}{$profile};
            }
        }
    }

    return $self;
}

sub user_config {
    my $self = shift;

    my @git_config_cmd = (qw{ git config --get-regexp ^lint });

    my ( $stdout, $stderr, $exit ) = Git::Lint::Command::run( \@git_config_cmd );

    # if there is no user config, the git config command above will return 1
    # but without stderr.
    die "git-lint: $stderr\n" if $exit && $stderr;

    my %parsed_config = ();
    foreach my $line ( split( /\n/, $stdout ) ) {
        next unless $line =~ /^lint\.(\w+).(\w+).(\w+)\s+(.+)$/;
        my ( $cat, $check, $profile, $value ) = ( $1, $2, $3, $4 );

        my @values = List::MoreUtils::apply {s/^\s+|\s+$//g} split( /,/, $value );
        push @{ $parsed_config{$cat}{$check}{$profile} }, @values;
    }

    return \%parsed_config;
}

1;

__END__