File Coverage

blib/lib/Git/Hooks/GerritChangeId.pm

Criterion	Covered	Total	%
statement	49	53	92.4
branch	7	14	50.0
condition	2	18	11.1
subroutine	11	11	100.0
pod	0	3	0.0
total	69	99	69.7

use warnings;

package Git::Hooks::GerritChangeId;
# ABSTRACT: Git::Hooks plugin to insert a Change-Id in a commit message
$Git::Hooks::GerritChangeId::VERSION = '3.3.1';
use v5.16.0;
use utf8;
use Carp;
use Log::Any '$log';
use Git::Hooks;
use Git::Message;
use Path::Tiny;

my $CFG = __PACKAGE__ =~ s/.*::/githooks./r;

##########

sub gen_change_id {
    my ($git, $msg) = @_;

    my $filename = Path::Tiny->tempfile(UNLINK => 1);
    open my $fh, '>', $filename ## no critic (RequireBriefOpen)
        or $git->fault("Internal error: can't open '$filename' for writing:", {details => $!})
        and croak;

    foreach my $info (
        [ tree      => [qw/write-tree/] ],
        [ parent    => [qw/rev-parse HEAD^0/] ],
        [ author    => [qw/var GIT_AUTHOR_IDENT/] ],
        [ committer => [qw/var GIT_COMMITTER_IDENT/] ],
    ) {
        my $value = eval { $git->run(@{$info->[1]}) };
        if (defined $value) {
            # It's OK if we can't find value.
            $fh->print("$info->[0] $value");
        }
    }

    $fh->print("\n", $msg);
    $fh->close();

    return 'I' . $git->run(qw/hash-object -t blob/, $filename);
}

sub insert_change_id {
    my ($git, $msg) = @_;

    # Does Change-Id: already exist? if so, exit (no change).
    return if $msg =~ /^Change-Id:/im;

    my $cmsg = Git::Message->new($msg);

    # Don't mess with the message if it's empty.
    if (   (! defined $cmsg->title || $cmsg->title !~ /\S/)
        && (! defined $cmsg->body  || $cmsg->body  !~ /\S/)
       ) {
        # (Signed-off-by footers don't count.)
        my @footer = $cmsg->get_footer_keys;
        return if @footer == 0 || @footer == 1 && $footer[0] eq 'signed-off-by';
    }

    # Insert the Change-Id footer
    $cmsg->add_footer_values('Change-Id' => gen_change_id($git, $cmsg->as_string));

    return $cmsg->as_string;
}

sub rewrite_message {
    my ($git, $commit_msg_file) = @_;

    $log->debug(__PACKAGE__ . "::rewrite_message($commit_msg_file)");

    my $msg = eval { $git->read_commit_msg_file($commit_msg_file) };
    unless (defined $msg) {
        $git->fault("Internal error: cannot read commit message file '$commit_msg_file'",
                    {details => $@});
        return 0;
    }

    # Rewrite the message file
    if (my $new_msg = insert_change_id($git, $msg)) {
        $git->write_commit_msg_file($commit_msg_file, $new_msg);
    }

    return 1;
}

# Install hooks
APPLYPATCH_MSG(\&rewrite_message);
COMMIT_MSG(\&rewrite_message);

1;

__END__