File Coverage

blib/lib/Git/Helpers/CPAN.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	8	10	80.0
condition			n/a
subroutine	9	9	100.0
pod			n/a
total	47	49	95.9

package Git::Helpers::CPAN;
our $VERSION = '1.000000';
use Moo;

use MetaCPAN::Client ();
use Try::Tiny qw( try );
use Types::Standard qw( HashRef InstanceOf Maybe Str );

has _client => (
    is      => 'ro',
    isa     => InstanceOf ['MetaCPAN::Client'],
    lazy    => 1,
    default => sub { MetaCPAN::Client->new },
);

has _latest_release => (
    is      => 'ro',
    isa     => InstanceOf ['MetaCPAN::Client::Release'],
    lazy    => 1,
    builder => '_build_latest_release',
);

has release_name => (
    is      => 'ro',
    isa     => Str,
    lazy    => 1,
    builder => '_build_release_name',
);

has name => (
    is       => 'ro',
    isa      => Str,
    required => 1,
);

has repository => (
    is       => 'ro',
    isa      => Maybe [HashRef],
    lazy     => 1,
    init_arg => undef,
    builder  => '_build_repository',
);

sub _build_repository {
    my $self = shift;

    return $self->_latest_release
        ? $self->_latest_release->resources->{repository}
        : undef;
}

sub _build_release_name {
    my $self = shift;

    return $self->name if $self->name !~ m{::};

    my $release_name;
    try {
        my $module = $self->_client->module( $self->name );
        $release_name = $module->distribution if $module;
    };

    if ( !$release_name ) {
        die sprintf( "Cannot find a module named %s", $self->name );
    }

    return $release_name;
}

sub _build_latest_release {
    my $self = shift;

    my $release;
    try {
        $release = $self->_client->release( $self->release_name );
    };

    if ( !$release ) {
        die sprintf( "Cannot find a release named %s", $self->release_name );
    }
    return $release;
}

1;

# ABSTRACT: Get repository information for a CPAN module or release

__END__