File Coverage

blib/lib/Git/FastExport.pm

Criterion	Covered	Total	%
statement	52	56	92.8
branch	18	22	81.8
condition	3	3	100.0
subroutine	8	8	100.0
pod	2	2	100.0
total	83	91	91.2

package Git::FastExport;
$Git::FastExport::VERSION = '0.108';
use strict;
use warnings;
use Carp;
use Scalar::Util qw( blessed );

use Git::Repository;
use Git::FastExport::Block;

my $LF = "\012";

sub new {
    my ( $class, $handle ) = @_;
    return bless { stream => $handle }, $class;
}

sub next_block {
    my ($self) = @_;
    my $fh = $self->{stream};
    return if !defined $fh;

    my $block = bless {}, 'Git::FastExport::Block';

    # pick up the header from the previous round, or read it (first time)
    $self->{header} ||= <$fh>;
    $block->{header} = delete $self->{header};

    # nothing left to process
    return if !defined $block->{header};

    chomp $block->{header};
    ( $block->{type} ) = $block->{header} =~ /^(\w+)/g;

    local $_;
    while (<$fh>) {

        # we've reached the beginning of the next block
        if (/^(commit|tag|reset|blob|checkpoint|progress|feature|option|done)\b/) {
            s/^progress /progress [$self->{source}] / if exists $self->{source};
            $self->{header} = $_;
            last;
        }

        chomp;

        # special case of data block
        if (/^data (.*)/) {
            if ( substr( $1, 0, 2 ) eq '<<' ) {    # Delimited format

                # 'data' SP '<<'  LF
                #  LF
                #  LF
                # LF?
                my $delim = substr( $1, 2 );
                local $/ = "$LF$delim$LF";
                chomp( $block->{data} = <$fh> );
            }
            else {                                 # Exact byte count format

                # 'data' SP  LF
                #  LF?
                my $bytes = $1;
                if ($bytes) {
                    local $/ = \$bytes;
                    $block->{data} = <$fh>;
                }
                else {
                    $block->{data} = "";
                }
            }
        }
        elsif (/^(?:[MDRC] |deleteall)/) {
            push @{ $block->{files} }, $_;
        }
        elsif (/^(\w+)/) {
            push @{ $block->{$1} }, $_;
        }
        else {

            # ignore empty lines, but choke on others
            die "Unexpected line:\n$_\n" if !/^$/;
            $block->{footer} .= "\012";
        }
    }

    # post-processing
    if ( $block->{type} eq 'commit' ) {
        ( $block->{committer_date} )
            = $block->{committer}[0] =~ /^committer [^>]*> (\d+) [-+]\d+$/g;
        ( $block->{author_date} )
            = $block->{author}[0] =~ /^author [^>]*> (\d+) [-+]\d+$/g;
    }

    return $block;
}

'progress 1 objects';

__END__