File Coverage

blib/lib/Getopt/Kingpin/Flags.pm

Criterion	Covered	Total	%
statement	85	85	100.0
branch	14	14	100.0
condition			n/a
subroutine	14	14	100.0
pod	7	7	100.0
total	120	120	100.0

package Getopt::Kingpin::Flags;
use 5.008001;
use strict;
use warnings;
use Object::Simple -base;
use Getopt::Kingpin::Flag;
use Carp;

our $VERSION = "0.10";

has _flags => sub {
    return {};
};

sub add {
    my $self = shift;
    my $hash = {@_};
    my ($name, $description) = ($hash->{name}, $hash->{description});

    if (exists $self->_flags->{$name}) {
        croak sprintf "flag %s is already exists", $name;
    }

    $self->_flags->{$name} = Getopt::Kingpin::Flag->new(
        name        => $name,
        description => $description,
        index       => (scalar keys %{$self->_flags}),
    );

    return $self->_flags->{$name};
}

sub unshift {
    my $self = shift;
    my @flags = @_;

    my $index_offset = scalar @flags;
    foreach my $name ($self->keys) {
        if ($name ne "help") {
            $self->_flags->{$name}->index($self->_flags->{$name}->index + $index_offset);
        }
    }

    my $index = 1;
    foreach my $f (@flags) {
        my $name = $f->name;

        if ($name eq "help") {

        } else {
            $f->index($index);
            $self->_flags->{$name} = $f;
            $index++;
        }
    }
}

sub get {
    my $self = shift;
    my ($name) = @_;

    if (not exists $self->_flags->{$name}) {
        return;
    }

    return $self->_flags->{$name};

}

sub keys {
    my $self = shift;
    my @keys = sort {$self->_flags->{$a}->index <=> $self->_flags->{$b}->index} keys %{$self->_flags};
    @keys = grep {$self->_flags->{$_}->_hidden == 0} @keys;
    return @keys;
}

sub values {
    my $self = shift;
    my @values = map {$self->_flags->{$_}} $self->keys;
    return @values;
}

sub count {
    my $self = shift;
    return scalar $self->keys;
}

sub _help_length {
    my $self = shift;

    my $len = [0, 0, 0];
    foreach my $f (grep {$_->_hidden != 1} $self->values) {
        my $str = $f->help_str;

        for (my $i = 0; $i < scalar @{$len}; $i++) {
            if ($len->[$i] < length $str->[$i]) {
                $len->[$i] = length $str->[$i];
            }
        }
    }

    return $len;
}

sub help {
    my $self = shift;
    my $ret = "";

    $ret .= "Flags:\n";

    my $len = $self->_help_length;
    foreach my $f (grep {$_->_hidden != 1} $self->values) {
        my $x = "";

        my $long = $len->[1];
        if ($len->[0] > 0) {
            if (defined $f->short_name) {
                $x .= sprintf "  %s, %-${long}s  %s\n", @{$f->help_str};
            } else {
                $x .= sprintf "      %-${long}s  %s\n", @{$f->help_str}[1, 2];
            }
        } else {
            $x .= sprintf "  %-${long}s  %s\n", @{$f->help_str}[1, 2];
        }
        $x =~ s/ +$//;
        $ret .= $x;
    }
    return $ret;
}

1;
__END__