File Coverage

blib/lib/Geoffrey/Role/Action.pm

Criterion	Covered	Total	%
statement	52	52	100.0
branch	20	24	83.3
condition	2	3	66.6
subroutine	15	15	100.0
pod	12	12	100.0
total	101	106	95.2

package Geoffrey::Role::Action;

use utf8;
use strict;
use warnings FATAL => 'all';

$Geoffrey::Role::Action::VERSION = '0.000203';

sub new {
    my $class = shift;
    my $self  = {@_};

    # make converter required
    if ( !$self->{converter} ) {
        require Geoffrey::Exception::RequiredValue;
        Geoffrey::Exception::RequiredValue::throw_converter( __PACKAGE__ . '::new' );
    }
    return bless $self, $class;
}

sub dbh { return $_[0]->{dbh} }

sub converter { return $_[0]->{converter} }

sub add {
    require Geoffrey::Exception::NotSupportedException;
    return Geoffrey::Exception::NotSupportedException::throw_action( 'add', shift );
}

sub alter {
    require Geoffrey::Exception::NotSupportedException;
    return Geoffrey::Exception::NotSupportedException::throw_action( 'alter', shift );
}

sub drop {
    require Geoffrey::Exception::NotSupportedException;
    return Geoffrey::Exception::NotSupportedException::throw_action( 'drop', shift );
}

sub list_from_schema {
    require Geoffrey::Exception::NotSupportedException;
    return Geoffrey::Exception::NotSupportedException::throw_action( 'list_from_schema', shift );
}

sub dryrun {
    my ( $self, $dryrun ) = @_;
    return $self->{dryrun} if !defined $dryrun;
    $self->{dryrun} = $dryrun;
    return $self;
}

sub for_table {
    my ( $self, $for_table ) = @_;
    return $self->{for_table} if !defined $for_table;
    $self->{for_table} = $for_table;
    return $self;
}

sub do {
    my ( $self, $s_sql ) = @_;
    return $s_sql if $self->dryrun;
    require Geoffrey::Exception::Database;
    Geoffrey::Exception::Database::throw_no_dbh() if !$self->dbh;
    $self->dbh->do($s_sql) or Geoffrey::Exception::Database::throw_sql_handle( $!, $s_sql );
    return $s_sql;
}

sub do_arrayref {
    my ( $self, $s_sql, $options ) = @_;
    return unless $s_sql;
    return [] if $self->dryrun;
    require Geoffrey::Exception::Database;
    Geoffrey::Exception::Database::throw_no_dbh() if !$self->dbh;
    return $self->dbh->selectall_arrayref( $s_sql, { Slice => {} }, @{$options} )
      || Geoffrey::Exception::Database::throw_sql_handle( $!, $s_sql );
}

sub do_prepared {
    my ( $self, $s_sql, $ar_values ) = @_;
    return $s_sql if $self->dryrun;
    require Carp;
    my $obj_prepared_statement = $self->dbh->prepare($s_sql) or Carp::longmess( $!, $s_sql );
    $obj_prepared_statement->execute( @{$ar_values} ) or Carp::longmess( $!, $s_sql );
    return $s_sql;
}

1;    # End of Geoffrey::Role::Action

__END__