File Coverage

blib/lib/Games/Sudoku/Component/Table/Cell.pm

Criterion	Covered	Total	%
statement	49	50	98.0
branch	17	18	94.4
condition	9	12	75.0
subroutine	15	16	93.7
pod	10	10	100.0
total	100	106	94.3

package Games::Sudoku::Component::Table::Cell;
{
  use strict;
  use warnings;
  use Carp;

  our $VERSION = '0.01';

  use base qw/Games::Sudoku::Component::Base/;

  sub _initialize {
    my ($this, %options) = @_;

    $this->{row}  = $this->_check($options{row});
    $this->{col}  = $this->_check($options{col});

    my $perm = $options{permission} || $options{perm};

    croak 'Invalid perm: '.(ref $perm)
      if ref $perm ne 'Games::Sudoku::Component::Table::Permission';

    $this->{perm} = $perm;

    $this->{value}    = 0;
    $this->{tmpvalue} = 0;

    $this->{locked}   = 0;
  }

  sub row       { $_[0]->{row} }
  sub col       { $_[0]->{col} }
  sub realvalue { $_[0]->{value} || 0; }
  sub tmpvalue  { $_[0]->{tmpvalue}; }

  sub lock      { $_[0]->{locked} = 1; }
  sub unlock    { $_[0]->{locked} = 0; }
  sub is_locked { $_[0]->{locked}; }

  sub value {
    my ($this, $value) = @_;

    if (defined $value && !$this->{locked}) {
      my $old = $this->{value};
      my $row = $this->{row};
      my $col = $this->{col};

      if ($old) {
        $this->{value} = 0;
        $this->{perm}->allow($row,$col,$old);
      }

      if ($value && !$this->is_allowed($value)) {
        $this->{tmpvalue} = $this->_check($value);
        $value = 0;
      }
      else {
        $this->{tmpvalue} = 0;
        $this->{value} = $this->_check0($value);
      }

      $this->{perm}->deny($row,$col,$value) if $value;
    }

    $this->{tmpvalue} || $this->{value} || 0;
  }

  sub is_allowed {
    my ($this, $value) = @_;

    return $this->{perm}->result(
      result => 0,
      reason => 'has other value'
    ) if $this->{value};

    $this->{perm}->is_allowed($this->{row},$this->{col},$value);
  }

  sub allowed {
    my $this = shift;

    return () if $this->{value};

    my @allowed = $this->{perm}->allowed($this->{row},$this->{col});
  }

  sub _permissions { $_[0]->{perm}; }
}

1;
__END__