File Coverage

blib/lib/Games/Solitaire/Verify/Column.pm

Criterion	Covered	Total	%
statement	71	72	98.6
branch	5	6	83.3
condition			n/a
subroutine	18	18	100.0
pod	10	10	100.0
total	104	106	98.1

package Games::Solitaire::Verify::Column;
$Games::Solitaire::Verify::Column::VERSION = '0.2402';
use warnings;
use strict;


use parent 'Games::Solitaire::Verify::Base';

use Games::Solitaire::Verify::Exception ();
use Games::Solitaire::Verify::Card      ();

__PACKAGE__->mk_acc_ref(
    [
        qw(
            _cards
            _s
            )
    ]
);


sub _from_string
{
    my ( $self, $str ) = @_;

    if ( $str !~ s{\A:(?: )?}{} )
    {
        Games::Solitaire::Verify::Exception::Parse::Column::Prefix->throw(
            error => "String does not start with \": \"", );
    }

    # Ignore trailing whitespace, so we don't have -1.
    my @cards = split( / +/, $str );

    $self->_cards(
        [
            map { Games::Solitaire::Verify::Card->new( { string => $_ } ) }
                @cards
        ]
    );

    $self->_recalc;

    return;
}

sub _init
{
    my ( $self, $args ) = @_;

    if ( exists( $args->{string} ) )
    {
        return $self->_from_string( $args->{string} );
    }
    elsif ( exists( $args->{cards} ) )
    {
        $self->_cards( $args->{cards} );

        $self->_recalc;
        return;
    }
    else
    {
        die "Cannot init - no 'string' or 'cards' specified.";
    }
}


sub len
{
    my $self = shift;

    return scalar( @{ $self->_cards() } );
}


sub pos
{
    my $self = shift;
    my $idx  = shift;

    return $self->_cards->[$idx];
}


sub top
{
    my $self = shift;

    return $self->pos(-1);
}


sub clone
{
    my $self = shift;

    my $new_col = Games::Solitaire::Verify::Column->new(
        {
            cards => [ map { $_->clone() } @{ $self->_cards() } ],
        }
    );

    return $new_col;
}


sub append_cards
{
    my ( $S, $c ) = @_;
    push @{ $S->_cards() }, @$c;
    $S->_recalc;
    return;
}


sub append
{
    my ( $self, $more_cards ) = @_;

    my $more_copy = $more_cards->clone();

    return $self->append_cards( $more_copy->_cards );
}


sub push
{
    my ( $self, $card ) = @_;

    push @{ $self->_cards() }, $card;

    $self->_recalc;

    return;
}


sub pop
{
    my $self = shift;

    my $card = pop( @{ $self->_cards() } );

    $self->_recalc;

    return $card;
}


sub popN
{
    my ( $S, $c ) = @_;

    my @r = splice( @{ $S->_cards() }, -$c );

    $S->_recalc;

    return \@r;
}


sub _recalc
{
    my $self = shift;

    $self->_s(
        join( ' ', ':', ( map { $_->fast_s() } @{ $self->_cards() } ) ) );

    return;
}

sub to_string
{
    return shift->_s;
}

1;    # End of Games::Solitaire::Verify::Column

__END__