File Coverage

blib/lib/Games/SMTNocturne/Demons/Fusion.pm

Criterion	Covered	Total	%
statement	13	57	22.8
branch	0	26	0.0
condition	0	5	0.0
subroutine	5	15	33.3
pod	5	10	50.0
total	23	113	20.3

package Games::SMTNocturne::Demons::Fusion;
BEGIN {
  $Games::SMTNocturne::Demons::Fusion::AUTHORITY = 'cpan:DOY';
}
$Games::SMTNocturne::Demons::Fusion::VERSION = '0.02';
use strict;
use warnings;
use overload '""' => 'to_string';
# ABSTRACT: represents the results of a fusion

use Games::SMTNocturne::Demons::Demon;


sub new {
    my ($class, $options, $demon1, $demon2, $sacrifice, $kagutsuchi) = @_;

    my $attrs = {};

    $demon1 = Games::SMTNocturne::Demons::Demon->from_name($demon1)
        unless ref($demon1);
    $demon2 = Games::SMTNocturne::Demons::Demon->from_name($demon2)
        unless ref($demon2);
    $attrs->{demons} = [ sort { $a->name cmp $b->name } $demon1, $demon2 ];

    if ($sacrifice) {
        if ($sacrifice eq '') {
            $attrs->{deathstone} = 1;
        }
        else {
            $sacrifice = Games::SMTNocturne::Demons::Demon->from_name($sacrifice)
                unless ref($sacrifice);
            $attrs->{sacrifice} = $sacrifice;
        }
    }

    $attrs->{kagutsuchi} = $kagutsuchi;
    $attrs->{options} = $options || {};

    return bless $attrs, $class;
}


sub options    { $_[0]->{options} }
sub demons     { $_[0]->{demons} }
sub sacrifice  { $_[0]->{sacrifice} }
sub deathstone { $_[0]->{deathstone} }
sub kagutsuchi { $_[0]->{kagutsuchi} }
sub result {
    my $self = shift;
    require Games::SMTNocturne::Demons;
    $self->{result} ||= Games::SMTNocturne::Demons::fuse(
        @{ $self->demons },
        {
            %{ $self->options },
            sacrifice  => $self->sacrifice,
            deathstone => $self->deathstone,
            kagutsuchi => @{ $self->kagutsuchi || [] }[0],
        }
    );
}

sub all_demons {
    my $self = shift;

    return (
        @{ $self->demons },
        ($self->sacrifice ? ($self->sacrifice) : ()),
    );
}

sub raw {
    my $self = shift;
    my $array = [ $self->options, @{ $self->demons } ];
    push @$array, $self->sacrifice
        if $self->sacrifice;
    push @$array, ""
        if $self->deathstone;
    push @$array, $self->kagutsuchi
        if defined $self->kagutsuchi;
    return $array;
}

sub to_string {
    my $self = shift;

    my $str = "Fuse " . $self->demons->[0]
            . " with " . $self->demons->[1];

    $str .= " while sacrificing " . $self->sacrifice
        if $self->sacrifice;
    $str .= " while sacrificing a deathstone"
        if $self->deathstone;
    $str .= " when Kagutsuchi is at phase "
          . join(", ", map { "$_/8" } @{ $self->kagutsuchi })
        if defined $self->kagutsuchi;
    $str .= " resulting in " . $self->result;

    return $str;
}


1;

__END__