File Coverage

blib/lib/Games/Nintendo/Mario/NSMB.pm

Criterion	Covered	Total	%
statement	25	27	92.5
branch	4	6	66.6
condition			n/a
subroutine	9	11	81.8
pod	3	3	100.0
total	41	47	87.2

use 5.20.0;
use warnings;
package Games::Nintendo::Mario::NSMB 0.209;
# ABSTRACT: a class for stylus-enabled Italian plumbers

use parent qw(Games::Nintendo::Mario);

use Carp ();

#pod =head1 SYNOPSIS
#pod
#pod   use Games::Nintendo::Mario::NSMB;
#pod
#pod   my $hero = Games::Nintendo::Mario::SMB->new(
#pod    name  => 'Luigi',
#pod    state => 'normal',
#pod   );
#pod
#pod   $hero->powerup('mushroom'); # doop doop doop!
#pod   $hero->powerup('flower');   # change clothes
#pod
#pod   $hero->damage for (1 .. 2); # cue the Mario Death Music
#pod
#pod =head1 DESCRIPTION
#pod
#pod This class subclasses Games::Nintendo::Mario, providing a model of the behavior
#pod of the Mario Brothers in New Super Mario Brothers.  All of the methods
#pod described in the Mario interface exist as documented.
#pod
#pod =head2 NAMES
#pod
#pod The plumber may be named Mario or Luigi.
#pod
#pod =head2 STATES
#pod
#pod The plumber's state may be any of: normal super fire shell mini mega
#pod
#pod =head2 POWERUPS
#pod
#pod Valid powerups are: mushroom flower shell mega_mushroom mini_mushroom
#pod
#pod =method games
#pod
#pod This ruleset reflects Mario in New Super Mario Bros., the first SMB game for
#pod Nintendo DS.
#pod
#pod =cut

sub _names  { qw[Mario Luigi] }
sub _states { qw[normal super fire shell mini mega] }
sub _items  { qw[mushroom flower shell mega_mushroom mini_mushroom] }

my %__default_behavior = (
  damage   => 'dead',
  mushroom => 'super',
  flower   => 'fire',
  shell    => 'shell',
  mega_mushroom => 'mega',
  mini_mushroom => 'mini',
);

my %state = (
  normal => { %__default_behavior },
  super  => {
    %__default_behavior,
    damage   => 'normal',
    mushroom => 'save',
  },
  fire   => {
    %__default_behavior,
    damage   => 'normal',
    flower   => 'save',
    mushroom => 'save',
  },
  shell  => {
    %__default_behavior,
    damage   => 'super',
    mushroom => 'save',
    flower   => 'save',
  },
  mega   => { map { $_ => 'ignore' } keys %__default_behavior },
  mini   => { %__default_behavior, mini => 'save' },
);

sub games {
  return ('New Super Mario Bros.');
}

sub _set_state {
  my ($self, $state, $item) = @_;

  if ($state eq 'save') {
    $self->{saved_item} = $item;
  } else {
    $self->{state} = $state;
  }
  return $self;
}

sub powerup {
  my ($self, $item) = @_;

  my $state = $self->state;
  Carp::confess "current state unknown"
    unless my $state_info = $state{ $state };

  Carp::confess "behavior for $item in $state unknown"
    unless my $new_state = $state_info->{$item};
  $self->_set_state($new_state, $item);
}

sub damage {
  my ($self) = @_;
  $self->powerup('damage');
}

"Go Wigi!";

__END__