File Coverage

blib/lib/Games/Lineofsight.pm

Criterion	Covered	Total	%
statement	12	54	22.2
branch	0	10	0.0
condition	0	9	0.0
subroutine	4	8	50.0
pod	0	4	0.0
total	16	85	18.8

package Games::Lineofsight;

use 5.008;
use strict;
use warnings;
require Exporter;

our @ISA = qw(Exporter);
our %EXPORT_TAGS = ( 'all' => [ qw(get_barriers analyze_map lineofsight) ] );
our @EXPORT_OK = ( @{ $EXPORT_TAGS{'all'} } );
our @EXPORT = qw( );
our $VERSION = '1.0';

use Math::Complex;

# returns map where the non-visible squares are replaced with $hidden_str
# $map          == reference to $map[$width][$height]
# $man_x,$man_y == location of the viewer
# $barrier_str  == the square in the map that identifies the barrier; for example "X"
# $hidden_str   == string that replaces non-visible squares
sub lineofsight{
   my($map,$man_x,$man_y,$barrier_str,$hidden_str)=@_;
   my($width)=scalar(@{@$map[0]});
   my($height)=scalar(@$map);

   # read the barriers
   my %barrier=get_barriers($width,$height,\@$map,$barrier_str);

   # recreate the map and replace the squares behind the barriers with $hidden_str
   my @map2=analyze_map($width,$height,\@$map,\%barrier,$man_x,$man_y,$hidden_str);

   return(@map2);
}

# returns barrier coordinates in a hash needed for analyze_map() -subroutine
# $width        == width of the map
# $height       == height of the map
# $map          == reference to $map[$width][$height]
# $barrier_str  == the square in the map that identifies the barrier; for example "X"
sub get_barriers{
   my($width,$height,$map,$barrier_str)=@_;
   my($i,$j)=undef;
   my %barrier=();
   for($i=0;$i < $height;$i++){
      for($j=0;$j < $width;$j++){
         $barrier{"$i,$j"}=1 if($$map[$i][$j] =~ /$barrier_str/);
      }
   }
   return %barrier;
}

# returns map where the non-visible squares are replaced with $hidden_str
# $width        == width of the map
# $height       == height of the map
# $map          == reference to $map[$width][$height]
# $barrier      == reference to barrier hash. Hash can be generated using the get_barriers() -subroutine.
# $man_x,$man_y == location of the viewer
# $hidden_str   == string that replaces non-visible squares
sub analyze_map{
   my($width,$height,$map,$barrier,$man_x,$man_y,$hidden_str)=@_;
   my($e,$i,$j,$hidden,$xx,$yy)=undef;
   my @map2=();
   for($i=0;$i < $height;$i++){
      for($j=0;$j < $width;$j++){

         # set the square visible
         $hidden=0;

         # browse all barriers
         foreach $e(keys %$barrier){

            # get the barrier x- and y- coordinate
            ($yy,$xx)=split ",",$e;

            # declare the location as hidden if it's behind this barrier
            if(($xx != $j || $yy != $i) && los($man_x,$man_y,$xx,$yy,$j,$i) < .5){
                $hidden=1;
                last;
            }
         }

         # set the location as hidden or normal to the output-map
         $map2[$i][$j]=($hidden ? $hidden_str : $$map[$i][$j]);

      }
   }
   return(@map2);
}

# checks if the viewer sees the chosen location because of a barrier
# returns <.5 if the viewer don't see the chosen location because of a barrier
# x1,y1 == location of the viewer
# x2,y2 == location of the barrier
# x3,y3 == location of the chosen position
sub los{
    my($x1,$y1,$x2,$y2,$x3,$y3)=@_;

    # line from the man to the barrier
    my $dx1=$x2-$x1;
    my $dy1=$y2-$y1;
    my $length1=sqrt($dx1*$dx1+$dy1*$dy1);
    return 10 unless($length1); # return if barrier and man overlap

    # line from the man to the chosen position
    my $dx2=$x3-$x1;
    my $dy2=$y3-$y1;
    my $length2=sqrt($dx2*$dx2+$dy2*$dy2);

    # return if the man and the chosen position overlap or
    # if the chosen position is nearer the man than the barrier
    return 10 if($length2 <= $length1 || !$length2);

    # cut the line to the barrier to the same length than the line to the
    # chosen position
    my $lengthdivisor=$length2/$length1;
    $dx2/=$lengthdivisor;
    $dy2/=$lengthdivisor;

    # return the distance of the lines's heads
    my $ddx=$dx1-$dx2;
    my $ddy=$dy1-$dy2;
    return sqrt($ddx*$ddx+$ddy*$ddy);
}

1;

__END__