File Coverage

blib/lib/Games/Bowling/Scorecard.pm

Criterion	Covered	Total	%
statement	53	53	100.0
branch	12	12	100.0
condition	12	12	100.0
subroutine	12	12	100.0
pod	8	8	100.0
total	97	97	100.0

use strict;
use warnings;
package Games::Bowling::Scorecard;
{
  $Games::Bowling::Scorecard::VERSION = '0.105';
}
# ABSTRACT: score your bowling game easily


use Games::Bowling::Scorecard::Frame;


sub new {
  my ($class) = @_;

  my $self = bless { frames => [ ] } => $class;

  return $self;
}


sub frames {
  my ($self) = @_;

  return @{ $self->{frames} };
}


sub current_frame {
  my ($self) = @_;

  return if $self->is_done;

  my @frames = $self->frames;

  my $frame = pop @frames;

  return $self->_next_frame if !$frame || $frame->is_done;

  return $frame;
}

sub _next_frame {
  my ($self) = @_;

  my $frame = $self->frames == 9
            ? do {
                require Games::Bowling::Scorecard::Frame::TenPinTenth;
                Games::Bowling::Scorecard::Frame::TenPinTenth->new;
              }
            : Games::Bowling::Scorecard::Frame->new;

  push @{ $self->{frames} }, $frame;

  return $frame;
}


sub pending_frames {
  my ($self) = @_;

  my @pending_frames = grep { $_->is_pending } $self->frames;
}


sub record { ## no critic Ambiguous
  my ($self, @balls) = @_;

  for my $ball (@balls) {
    Carp::croak "can't record more balls on a completed scorecard"
      if $self->is_done;

    for my $pending ($self->pending_frames) {
      $pending->record($ball);
    }

    $self->current_frame->record($ball);
  }
}


sub score {
  my ($self) = @_;

  my $score = 0;
  $score += $_->score for $self->frames;

  return $score;
}


sub score_through {
  my ($card, $n) = @_;

  Carp::croak "frame out of range" unless $n >= 1 and $n <= 10;

  my @frames = $card->frames;
  my $score = 0;

  INDEX: for my $idx (0 .. $n - 1) {
    my $frame = $frames[ $idx ];
    return undef if $frame->is_pending or not $frame->is_done;

    $score += $frame->score;
  }

  return $score;
}


sub is_done {
  my ($self) = @_;

  my @frames = $self->frames;

  return (@frames == 10 and $frames[9]->is_done);
}


300;

__END__