File Coverage

blib/lib/Games/Board/Space.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	11	18	61.1
condition	2	3	66.6
subroutine	11	11	100.0
pod	8	8	100.0
total	76	84	90.4

use strict;
use warnings;
package Games::Board::Space 1.014;
# ABSTRACT: a parent class for spaces on game board

use Carp;

#pod =head1 SYNOPSIS
#pod
#pod   use Games::Board;
#pod
#pod   my $board = Games::Board->new;
#pod
#pod   $board->add_space(Games::Board::Space->new(
#pod     id   => 'go',
#pod     dir  => { next => 'mediterranean', prev => 'boardwalk' },
#pod     cost => undef
#pod   ));
#pod
#pod   my $tophat = Games::Board::Piece->new(id => 'tophat')->move(to => 'go');
#pod
#pod =head1 DESCRIPTION
#pod
#pod This module provides a base class for representing the spaces on a game board.
#pod
#pod =cut

#pod =method new
#pod
#pod This method constructs a new space and returns it.
#pod
#pod =cut

sub new {
  my $class = shift;
  my %args  = @_;

  return unless $args{id};
  croak "no board supplied in space creation"
    unless eval { $args{board}->isa('Games::Board') };

  my $space = {
    id    => $args{id},
    board => $args{board},
  };

  $space->{dir} = $args{dir}
    if $args{dir} and (ref $args{dir} eq 'HASH');

  bless $space => $class;
}

#pod =method id
#pod
#pod This method returns the id of the space.
#pod
#pod =cut

sub id {
  my $space = shift;

  return $space->{id};
}

#pod =method board
#pod
#pod This method returns board on which this space sits.
#pod
#pod =cut

sub board {
  my $space = shift;
  $space->{board};
}

#pod =method dir_id
#pod
#pod   my $id = $space->dir_id($dir);
#pod
#pod This method returns the id of the space found in the given direction from this
#pod space.
#pod
#pod =cut

sub dir_id {
  my ($space, $dir) = @_;

  return $space->{dir}{$dir} if (ref $space->{dir} eq 'HASH');
}

#pod =method dir
#pod
#pod   my $new_space = $space->dir($dir);
#pod
#pod This method returns the space found in the given direction from this space.
#pod
#pod =cut

sub dir {
  my ($space, $dir) = @_;
  $space->board->space($space->dir_id($dir));
}

#pod =method contains
#pod
#pod   my $bool = $space->contains($piece);
#pod
#pod This method returns a true value if the space contains the passed piece.
#pod
#pod =cut

sub contains {
  my ($self, $piece) = @_;
  return 1 if grep { $_ eq $piece->id } @{$self->{contents}};
}

#pod =method receive
#pod
#pod   $space->receive($piece);
#pod
#pod This method will place the given piece onto this space.
#pod
#pod =cut

sub receive {
  my ($self, $piece) = @_;

  return unless eval { $piece->isa('Games::Board::Piece') };
  return if $self->contains($piece);

  $piece->{current_space} = $self->id;
  push @{$self->{contents}}, $piece->id;
}

#pod =method take
#pod
#pod   $space->take($piece);
#pod
#pod This method removes the piece from this space.
#pod
#pod =cut

sub take {
  my ($self, $piece) = @_;

  return unless eval { $piece->isa('Games::Board::Piece') };
  return unless $self->contains($piece);

  delete $piece->{current_space};
  $self->{contents} = [ grep { $_ ne $piece->id } @{$self->{contents}} ];
}

1;

__END__