File Coverage

blib/lib/Games/ABC_Path/Generator/App.pm

Criterion	Covered	Total	%
statement	20	45	44.4
branch	0	14	0.0
condition			n/a
subroutine	7	10	70.0
pod	1	1	100.0
total	28	70	40.0

package Games::ABC_Path::Generator::App;
$Games::ABC_Path::Generator::App::VERSION = '0.6.0';
use 5.006;
use strict;
use warnings;

use Pod::Usage qw(pod2usage);

use parent 'Games::ABC_Path::Generator::Base';

use Getopt::Long qw(GetOptionsFromArray);

use Games::ABC_Path::Generator;


sub _argv
{
    my $self = shift;

    if (@_)
    {
        $self->{_argv} = shift;
    }

    return $self->{_argv};
}

sub _init
{
    my ( $self, $args ) = @_;

    $self->_argv( $args->{argv} );

    return;
}


sub run
{
    my ($self) = @_;

    my $seed;
    my $mode = 'riddle';
    my $man  = 0;
    my $help = 0;
    if (
        !GetOptionsFromArray(
            $self->_argv(),
            'seed=i' => \$seed,
            'mode=s' => \$mode,
            'help|h' => \$help,
            man      => \$man,
        )
        )
    {
        pod2usage(2);
    }

    if ($help)
    {
        pod2usage(1);
    }
    elsif ($man)
    {
        pod2usage( -verbose => 2 );
    }
    elsif ( !defined($seed) )
    {
        die "Seed not specified! See --help.";
    }
    else
    {
        my $gen = Games::ABC_Path::Generator->new( { seed => $seed, } );

        if ( $mode eq 'final' )
        {
            print $gen->calc_final_layout()->as_string( {} );
        }
        elsif ( $mode eq 'riddle' )
        {
            my $riddle        = $gen->calc_riddle();
            my $riddle_string = $riddle->get_riddle_v1_string;

            print sprintf( "ABC Path Solver Layout Version 1:\n%s",
                $riddle_string, );
        }

    }
    return;
}


1;    # End of Games::ABC_Path::Generator::App

__END__