File Coverage

blib/lib/GD/Barcode/EAN8.pm

Criterion	Covered	Total	%
statement	47	61	77.0
branch	4	14	28.5
condition			n/a
subroutine	9	10	90.0
pod	3	5	60.0
total	63	90	70.0

package GD::Barcode::EAN8;
use strict;
use warnings;

use GD::Barcode;
use parent qw(Exporter);
use vars qw($VERSION @ISA $errStr);
@ISA     = qw(GD::Barcode Exporter);
our $VERSION = '2.00';
my $leftOddBar = {
    '0' => '0001101',
    '1' => '0011001',
    '2' => '0010011',
    '3' => '0111101',
    '4' => '0100011',
    '5' => '0110001',
    '6' => '0101111',
    '7' => '0111011',
    '8' => '0110111',
    '9' => '0001011'
};
my $rightBar = {
    '0' => '1110010',
    '1' => '1100110',
    '2' => '1101100',
    '3' => '1000010',
    '4' => '1011100',
    '5' => '1001110',
    '6' => '1010000',
    '7' => '1000100',
    '8' => '1001000',
    '9' => '1110100'
};
my $guardBar  = 'G0G';
my $centerBar = '0G0G0';

sub new {
    my ( $sClass, $sTxt ) = @_;
    $errStr = '';
    my $oThis = {};
    bless $oThis, $sClass;
    return if ( $errStr = $oThis->init($sTxt) );
    return $oThis;
}

sub init {
    my ( $oThis, $sTxt ) = @_;

    #Check
    return 'Invalid Characters' if ( $sTxt =~ /[^0-9]/ );

    #CalcCd
    if ( length($sTxt) == 7 ) {
        $sTxt .= calcEAN8CD($sTxt);
    }
    elsif ( length($sTxt) == 8 ) {
        ;
    }
    else {
        return 'Invalid Length';
    }
    $oThis->{text} = $sTxt;
    return '';
}

sub calcEAN8CD {
    my ($sTxt) = @_;
    my ( $i, $iSum );

    my @aWeight = ( 3, 1, 3, 1, 3, 1, 3 );
    $iSum = 0;
    for ( $i = 0 ; $i < 7 ; $i++ ) {
        $iSum += substr( $sTxt, $i, 1 ) * $aWeight[$i];
    }
    $iSum %= 10;
    $iSum = ( $iSum == 0 ) ? 0 : ( 10 - $iSum );
    return "$iSum";
}

sub barcode {
    my ($oThis) = @_;
    my ( $i, $sRes );

    #(1) Init
    my $sTxt = $oThis->{text};
    $sRes = $guardBar;    #GUARD

    #(2) Left 4
    for ( $i = 0 ; $i < 4 ; $i++ ) {
        $sRes .= GD::Barcode::barPtn( substr( $sTxt, $i, 1 ), $leftOddBar );
    }

    #(3) Center
    $sRes .= $centerBar;

    #(4) Right 4 bytes
    for ( $i = 4 ; $i < 8 ; $i++ ) {
        $sRes .= GD::Barcode::barPtn( substr( $sTxt, $i, 1 ), $rightBar );
    }

    #(5)GUARD
    $sRes .= $guardBar;
    return $sRes;
}

sub plot {
    my ( $oThis, %hParam ) = @_;

    my $sPtn = $oThis->barcode();

    #Create Image
    require GD;
    my $iHeight = ( $hParam{Height} ) ? $hParam{Height} : 50;
    my ( $oGd, $cBlack );
    if ( $hParam{NoText} ) {
        ( $oGd, $cBlack ) =
          GD::Barcode::plot( $sPtn, length($sPtn), $iHeight, 0, 0 );
    }
    else {
        my ( $fW, $fH ) = ( GD::Font->Small->width, GD::Font->Small->height );
        my $iWidth = length($sPtn);

        ( $oGd, $cBlack ) =
          GD::Barcode::plot( $sPtn, $iWidth, $iHeight, $fH, 0 );
        $oGd->string(
            GD::Font->Small, $fW + 1,
            $iHeight - $fH,
            substr( $oThis->{text}, 0, 4 ), $cBlack
        );
        $oGd->string(
            GD::Font->Small, $fW + 33,
            $iHeight - $fH,
            substr( $oThis->{text}, 4, 4 ), $cBlack
        );
    }
    return $oGd;
}
1;
__END__