File Coverage

blib/lib/FusionInventory/Agent/Task/Inventory/Virtualization/Xen.pm

Criterion	Covered	Total	%
statement	32	41	78.0
branch	8	10	80.0
condition			n/a
subroutine	5	7	71.4
pod	0	2	0.0
total	45	60	75.0

package FusionInventory::Agent::Task::Inventory::Virtualization::Xen;

use strict;
use warnings;

use FusionInventory::Agent::Tools;

our $runMeIfTheseChecksFailed = ["FusionInventory::Agent::Task::Inventory::Virtualization::Libvirt"];

sub isEnabled {
    return canRun('xm');
}

sub doInventory {
    my (%params) = @_;

    my $inventory = $params{inventory};
    my $logger    = $params{logger};

    my $command = 'xm list';
    foreach my $machine (_getVirtualMachines(command => $command, logger => $logger)) {
        my $uuid = _getUUID(
            command => "xm list -l $machine->{NAME}",
            logger  => $logger
        );
        $machine->{UUID} = $uuid;
        $inventory->addEntry(
            section => 'VIRTUALMACHINES', entry => $machine
        );
    }
}

sub _getUUID {
    my (%params) = @_;

    return getFirstMatch(
        pattern => qr/\( uuid \s ([^)]+) \)/x,
        %params
    );
}

sub  _getVirtualMachines {

    my $handle = getFileHandle(@_);

    return unless $handle;

    # xm status
    my %status_list = (
        'r' => 'running',
        'b' => 'blocked',
        'p' => 'paused',
        's' => 'shutdown',
        'c' => 'crashed',
        'd' => 'dying',
    );

    # drop headers
    my $line  = <$handle>;

    my @machines;
    while (my $line = <$handle>) {
        chomp $line;
        my ($name, $vmid, $memory, $vcpu, $status);
        my @fields = split(' ', $line);
        if (@fields == 4) {
                ($name, $memory, $vcpu) = @fields;
                $status = 'off';
        } else {
                ($name, $vmid, $memory, $vcpu, $status) = @fields;
                $status =~ s/-//g;
                $status = $status ? $status_list{$status} : 'off';
               next if $vmid == 0;
        }
        next if $name eq 'Domain-0';

        my $machine = {
            MEMORY    => $memory,
            NAME      => $name,
            STATUS    => $status,
            SUBSYSTEM => 'xm',
            VMTYPE    => 'xen',
            VCPU      => $vcpu,
        };

        push @machines, $machine;

    }
    close $handle;

    return @machines;
}

1;