File Coverage

blib/lib/Footprintless/Resource/UrlProvider.pm

Criterion	Covered	Total	%
statement	47	47	100.0
branch	9	12	75.0
condition			n/a
subroutine	12	12	100.0
pod	2	2	100.0
total	70	73	95.8

use strict;
use warnings;

package Footprintless::Resource::UrlProvider;
$Footprintless::Resource::UrlProvider::VERSION = '1.29';
# ABSTRACT: A resource provider for resources retrieved by URL
# PODNAME: Footprintless::Resource::UrlProvider

use parent qw(Footprintless::Resource::Provider);

use Carp;
use Footprintless::Resource::Url;
use Footprintless::Util qw(
    temp_file
);
use Log::Any;
use URI;

my $logger = Log::Any->get_logger();

sub _download {
    my ( $self, $resource, %options ) = @_;

    my $file;
    if ( $options{to} ) {
        $file = $options{to};
        if ( -d $file ) {
            my @segments = $resource->get_uri()->path_segments();
            $file = File::Spec->catfile( $file, $segments[$#segments] );
        }
    }
    else {
        my @suffix;
        if ( $resource->get_url() =~ /.*(\.\S*)$/ ) {
            $logger->tracef( 'preserving extension [%s] for resource %s', $1, $resource );
            push( @suffix, suffix => $1 );
        }

        $file = temp_file(@suffix);
    }

    my $response = $self->{agent}->get( $resource->get_uri(), ':content_file' => "$file" );
    croak( 'download failed: ', $response->message() )
        unless ( $response->is_success() );

    return $file;
}

sub _init {
    my ($self) = @_;

    $self->{agent} = $self->{factory}->agent();

    return $self;
}

sub resource {
    my ( $self, $spec ) = @_;

    return $spec if ( UNIVERSAL::isa( $spec, 'Footprintless::Resource::Url' ) );

    return Footprintless::Resource::Url->new( ref($spec) ? $spec->{url} : $spec );
}

sub supports {
    my ( $self, $resource ) = @_;

    return 1;
}

1;

__END__