File Coverage

blib/lib/Footprintless/Deployment.pm

Criterion	Covered	Total	%
statement	64	67	95.5
branch	12	18	66.6
condition	3	3	100.0
subroutine	16	16	100.0
pod	2	2	100.0
total	97	106	91.5

use strict;
use warnings;

package Footprintless::Deployment;
$Footprintless::Deployment::VERSION = '1.28';
# ABSTRACT: A deployment manager
# PODNAME: Footprintless::Deployment

use parent qw(Footprintless::MixableBase);

use Carp;
use File::Path qw(
    make_path
);
use Footprintless::Mixins qw (
    _clean
    _download
    _entity
    _extract_resource
    _resource
    _sub_entity
);
use Footprintless::Util qw(
    agent
    rebase
    temp_dir
);
use Log::Any;

my $logger = Log::Any->get_logger();

sub clean {
    my ( $self, @options ) = @_;
    $self->_clean(@options);
}

sub deploy {
    my ( $self, %options ) = @_;

    if ( $options{to_dir} ) {
        $self->_ensure_clean_dirs( $options{to_dir} );
        $self->_deploy_resources( $options{to_dir},
            ( $options{names} ? ( names => $options{names} ) : () ) );
        &{ $options{extra} }( $options{to_dir} ) if ( $options{extra} );
    }
    else {
        $self->_local_template(
            sub {
                my ( $to_dir, $resource_dir ) = @_;
                $self->_ensure_clean_dirs($to_dir);
                $self->_deploy_resources( $resource_dir,
                    ( $options{names} ? ( names => $options{names} ) : () ) );
                &{ $options{extra} }($to_dir) if ( $options{extra} );
            },
            rebase => $options{rebase}
        );
    }

    $logger->debug("deploy complete");
}

sub _deploy_resources {
    my ( $self, $to_dir, %options ) = @_;
    my $resources = $self->_sub_entity( 'resources', 1 );

    my @names =
        $options{names}
        ? @{ $options{names} }
        : keys(%$resources);

    $logger->debugf( "deploy %s to %s", \@names, $to_dir );
    foreach my $resource_name (@names) {
        my $resource = $resources->{$resource_name};
        if ( ref($resource) eq 'HASH' && $resource->{extract_to} ) {
            my $extract_dir = File::Spec->catdir( $to_dir, $resource->{extract_to} );
            $logger->tracef( 'extract [%s] to [%s]', $resource, $to_dir );
            $self->_extract_resource( $resource, $extract_dir );
        }
        else {
            $logger->tracef( 'download [%s] to [%s]', $resource, $to_dir );
            $self->_download( $resource, $to_dir );
        }
    }
}

sub _ensure_clean_dirs {
    my ( $self, $base_dir ) = @_;
    foreach my $dir ( $self->_relative_clean_dirs ) {
        make_path( File::Spec->catdir( $base_dir, $dir ) );
    }
}

sub _local_template {
    my ( $self, $local_work, @options ) = @_;
    $self->Footprintless::Mixins::_local_template(
        sub {
            my ($to_dir) = @_;

            my $resource_dir = $self->_sub_entity('resource_dir');
            $resource_dir =
                $resource_dir
                ? File::Spec->catdir( $to_dir, $resource_dir )
                : $to_dir;
            make_path($resource_dir);

            &$local_work( $to_dir, $resource_dir );
        },
        @options
    );
}

sub _relative_clean_dirs {
    my ($self) = @_;
    my $base = $self->_entity("$self->{coordinate}.to_dir");
    return
        map { m'/$' ? ( File::Spec->abs2rel( $_, $base ) ) : () }
        @{ $self->_entity("$self->{coordinate}.clean") };
}

1;

__END__