File Coverage

lib/Flux/Mapper.pm

Criterion	Covered	Total	%
statement	29	33	87.8
branch	9	12	75.0
condition	8	15	53.3
subroutine	6	7	85.7
pod			n/a
total	52	67	77.6

package Flux::Mapper;
{
  $Flux::Mapper::VERSION = '1.03';
}

# ABSTRACT: interface for transforming input or output streams.


use Moo::Role;

use Carp;
use Scalar::Util qw(blessed);

use Flux::Out;

use overload '|' => sub {
    my ($left, $right, $swap) = @_;

    require Flux::Mapper::MappedIn;
    require Flux::Mapper::MappedOut;
    require Flux::Mapper::MappedMapper;

    if ($swap) {
        ($left, $right) = ($right, $left);
    }
    unless (blessed $left and $left->can('does')) {
        croak "Left side of pipe is not a flux object, but '$left'";
    }
    unless (blessed $right and $right->can('does')) {
        croak "Right side of pipe is not a flux object, but '$right'";
    }

    if ($left->does('Flux::Mapper') and $right->does('Flux::Mapper')) {
        # m | m
        return Flux::Mapper::MappedMapper->new(left => $left, right => $right);
    }

    if ($left->does('Flux::Mapper') and $right->does('Flux::Out')) {
        # m | o
        return Flux::Mapper::MappedOut->new(mapper => $left, out => $right);
    }

    if ($left->does('Flux::In') and $right->does('Flux::Mapper')) {
        # i | m
        return Flux::Mapper::MappedIn->new(in => $left, mapper => $right);
    }

    croak "Strange arguments '$left' and '$right'";

}, '""' => sub { $_[0] }; # strangely, when I overload |, I need to overload other operators too...

requires 'write';

requires 'write_chunk';

requires 'commit';


1;

__END__