File Coverage

blib/lib/Finnigan/RawFileInfoPreamble.pm

Criterion	Covered	Total	%
statement	38	40	95.0
branch	2	4	50.0
condition			n/a
subroutine	11	11	100.0
pod	6	6	100.0
total	57	61	93.4

package Finnigan::RawFileInfoPreamble;

use strict;
use warnings FATAL => qw( all );
our $VERSION = 0.0206;

use Finnigan;
use base 'Finnigan::Decoder';

use overload ('""' => 'stringify');

sub decode {
  my ($class, $stream, $version) = @_;

  my @common_fields = (
                       "method file present"  => ['V',    'UInt32'],
                       year                   => ['v',    'UInt16'],
                       month                  => ['v',    'UInt16'],
                       "day of the week"      => ['v',    'UInt16'],
                       day                    => ['v',    'UInt16'],
                       hour                   => ['v',    'UInt16'],
                       minute                 => ['v',    'UInt16'],
                       second                 => ['v',    'UInt16'],
                       millisecond            => ['v',    'UInt16'],
                      );

  my %specific_fields;
  $specific_fields{8} = [],
  $specific_fields{57} = [
                          "unknown_long[2]"   => ['V',    'UInt32'],
                          "data addr"         => ['V',    'UInt32'],
                          "unknown_long[3]"   => ['V',    'UInt32'],
                          "unknown_long[4]"   => ['V',    'UInt32'],
                          "unknown_long[5]"   => ['V',    'UInt32'],
                          "unknown_long[6]"   => ['V',    'UInt32'],
                          "run header addr"   => ['V',    'UInt32'],
                          unknown_area        => ['C756', 'RawBytes'], # 804 - 12 * 4 (804 is the fixed size of RawFileInfoPreamble prior to v.64)
                         ];

  $specific_fields{60} = $specific_fields{57};
  $specific_fields{62} = $specific_fields{57};
  $specific_fields{63} = $specific_fields{57};

  $specific_fields{64} = [
                          "unknown_long[2]"                => ['V',     'UInt32'],
                          "32-bit data addr (unused)"      => ['V',     'UInt32'],
                          "unknown_long[3]"                => ['V',     'UInt32'],
                          "unknown_long[4]"                => ['V',     'UInt32'],
                          "unknown_long[5]"                => ['V',     'UInt32'],
                          "unknown_long[6]"                => ['V',     'UInt32'],
                          "32-b run header addr (unused)"  => ['V',     'UInt32'],
                          "unknown_area[1]"                => ['C760',  'RawBytes'],
                          "data addr"                      => ['Q<',    'UInt64'],
                          "unknown_long[7]"                => ['V',     'UInt32'],
                          "unknown_long[8]"                => ['V',     'UInt32'],
                          "run header addr"                => ['Q<',    'UInt64'],
                          "unknown_area[2]"                => ['C1008', 'RawBytes'],
                         ];

  if ($version == 66) {
    $specific_fields{66} = $specific_fields{64};
    $specific_fields{66}->[-1]->[0] = 'C1024'; # unknown_area[2] has been extended
  }

  die "don't know how to parse version $version" unless $specific_fields{$version};
  my $self = Finnigan::Decoder->read($stream, [@common_fields, @{$specific_fields{$version}}]);

  return bless $self, $class;
}

sub timestamp {
  my $self = shift;
  my @dow_abbr = qw/X Mon Tue Wed Thu Fri Sat Sun/;
  my @month_abbr = qw/X Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec/;
  $dow_abbr[$self->{data}->{"day of the week"}->{value}] . " "
    . $month_abbr[$self->{data}->{month}->{value}]
      . " "
        . $self->{data}->{day}->{value}
          . " "
            . $self->{data}->{year}->{value}
              . " "
                . $self->{data}->{hour}->{value}
                  . ":"
                    . $self->{data}->{minute}->{value}
                      . ":"
                        . $self->{data}->{second}->{value}
                          . "."
                            . $self->{data}->{millisecond}->{value}
                              ;
}

sub xmlTimestamp {
  my $self = shift;
  sprintf(
    '%04d-%02d-%02dT%02d:%02d:%02.0fZ',
    $self->{data}->{year}->{value},
    $self->{data}->{month}->{value},
    $self->{data}->{day}->{value},
    $self->{data}->{hour}->{value},
    $self->{data}->{minute}->{value},
    $self->{data}->{second}->{value} + $self->{data}->{millisecond}->{value} / 1000
  );
}

sub run_header_addr {
  shift->{data}->{"run header addr"}->{value};
}

sub data_addr {
  shift->{data}->{"data addr"}->{value};
}

sub stringify {
  my $self = shift;
  return $self->timestamp
      . "; "
        . "data addr: " . $self->data_addr
          . "; "
            . "RunHeader addr: " . $self->run_header_addr
              ;
}

1;
__END__