File Coverage

blib/lib/Finance/YahooProfile.pm

Criterion	Covered	Total	%
statement	12	133	9.0
branch	0	60	0.0
condition	0	15	0.0
subroutine	4	8	50.0
pod	1	2	50.0
total	17	218	7.8

package Finance::YahooProfile;

use strict;
use vars qw($VERSION);

$VERSION = '1.12';

use LWP::UserAgent;
use HTTP::Request::Common;

sub new {
    my $type = shift;
    my $class = ref $type || $type;
    my $self = {};
    bless $self, $class;
    $self->_init(@_) if @_;
    return $self;
}

sub _init {
    my ($self, %params) = @_;
    for (keys %params) {
	$self->{$_} = $params{$_};
	$self->{'dollar_symbol'} = 1 unless defined $params{'dollar_symbol'};
    }
}

sub profile {
    my ($self, %params) = @_;

    my (@res, $ua);

    $ua = LWP::UserAgent->new;
    $ua->timeout($self->{'timeout'}) if defined $self->{'timeout'};
    $ua->env_proxy();

    if (not ref $params{'s'}) { $params{'s'} = [$params{'s'}]; }

    my ($s, $firstletter, $url, $content, $res);
    for $s ( @{$params{'s'}} ) {

	$firstletter = substr($s, 0, 1);
	$url = "http://biz.yahoo.com/p/$firstletter/$s.html";
	$content = $ua->request(GET $url)->content();
	$res = {};  ## to store the results
	$res->{'requested_symbol'} = $s;

	{
	    local $/;
	    $content =~ s/<[^>]*>//gs;
	}

	## Prepare Content for extraction
	$content =~ s/ / /g;                         ## insert spaces
	$content =~ s/.*(Statistics at a Glance -- )//s;  ## remove the beginning
	$content =~ s/(See Profile).*//s;                 ## remove the end

	## Check for non-existent data
	if ($content =~ /\nNo Such Data/) {
	    $res->{'success'} = 0;
	    push (@res, $res);
	    next;
	}

	## Market
	$content =~ s/(.+?)://s;
	$res->{'market'} = $1;

	## Ticker Symbol
	if ($content =~ s/(.+?)As of //s) {
	    $res->{'symbol'} = $1;
	}

	## Last Updated
	if ($content =~ s/(.+?)Price and Volume//s) {
	    $res->{'last_updated'} = $1;
	}

	## 52-Week Prices
	if ($content =~ s/52-Week Lowon (.+?)\$(.+?) Recent Price(.+?) 52-Week Highon (.+?)\$(.+?)( )?Beta/Beta/s) {
	    $res->{'52_week_low_date'} = $1;
	    $res->{'52_week_low'} = $2;
	    $res->{'recent_price'} = $3;
	    $res->{'52_week_high_date'} = $4;
	    $res->{'52_week_high'} = $5;
	}

	## Beta, and Volume Data
	if ($content =~ s/Beta(.+?) Daily Volume \(3-month avg\)(.+?)Daily Volume \(10-day avg\)(.+?)Stock/Stock/s) {
	    $res->{'beta'} = $1;
	    $res->{'daily_volume_3ma'} = $2;
	    $res->{'daily_volume_10da'} = $3;
	}

	## 52-Week Price Change
	if ($content =~ s/.+?52-Week Change(.+?)52-Week Changerelative to S&P500(.+?)Share//s) {
	    $res->{'52_week_change'} = $1;
	    $res->{'52_week_change_sp500'} = $2;
	}

	## Share related items
	if ($content =~ s/.+?Market Capitalization(.+?)Shares Outstanding(.+?)Float(.+?)Dividends//s) {
	    $res->{'market_capitalization'} = $1;
	    $res->{'shares_outstanding'} = $2;
	    $res->{'shares_float'} = $3;
	}

	if ($content =~ s/.*?Annual Dividend( \(indicated\))?(.+?)( Dividend Yield(.+?))?Last Split(.+?)Per//s) {
	    $res->{'dividend'} = $2;
	    $res->{'dividend_yield'} = $4;

	    if ($5 ne 'none') {
		if ($5 =~ m/factor (.+?) on (.+)/) {
		    $res->{'last_split_factor'} = $1;
		    $res->{'last_split_date'} = $2;
		}
	    }
	}

	## Per-Share Data
	if ($content =~ s/.+?Book Value \(mrq\*\)(.+?) Earnings \(ttm\)(.+?) (Earnings \(mrq\)(.+?) )?Sales \(ttm\)(.+?) Cash( \(mrq\*\)?)?(.+?) Valuation//s) {
	    $res->{'book_value'} = $1;
	    $res->{'earnings_ttm'} = $2;
	    $res->{'earnings_mrq'} = $4;
	    $res->{'sales_ttm'} = $5;
	    $res->{'cash'} = $7;
	}

	## Valuation Ratios
	if ($content =~ s!.+?Price/Book \(mrq\*\)(.+?) Price/Earnings( \(ttm\))?(.+?) Price/Sales \(ttm\)(.+?) Income!!s) {
	    $res->{'price_book'} = $1;
	    $res->{'price_earnings'} = $3;
	    $res->{'price_sales'} = $4;
	}

	## Income Statements
	if ($content =~ s/.+?Sales \(ttm\)(.+?)EBITDA \(ttm\*\)(.+?)Income available to common \(ttm\)(.+?)Profitability//s) {
	    $res->{'sales'} = $1;
	    $res->{'ebitda'} = $2;
	    $res->{'income'} = $3;
	}

	## Profitability
	if ($content =~ s/.*?Profit Margin \(ttm\)(.+?)Operating Margin \(ttm\)(.+?)Fiscal//s) {
	    $res->{'profit_margin'} = $1;
	    $res->{'operating_margin'} = $2;
	}

	## Fiscal Year
	if ($content =~ s/.*?Fiscal Year Ends(.+?)Most recent quarter(\(fully\nupdated\))?(.+?)(Most recent quarter\(flash earnings\)(.+?))?Management//s) {
	    $res->{'fiscal_year_ends'} = $1;
	    $res->{'most_recent_quarter'} = $3;
	    $res->{'most_recent_quarter_fe'} = $5;
	    $res->{'fiscal_year_ends'} =~  s/\n|\r/ /s;

	    }

	## Management Effectiveness
	if ($content =~ s/.*?Return on Assets \(ttm\)(.+?)Return on Equity \(ttm\)(.+?)Financial//s) {
	    $res->{'return_on_assets'} = $1;
	    $res->{'return_on_equity'} = $2;
	}

	## Financial Strength
	if ($content =~ s/.*?Current Ratio( \(mrq\*?\))?(.+?) Debt\/Equity( \(mrq\*?\))?(.+?) Total Cash( \(mrq\*?\))?(.+?)Short//s) {
	    $res->{'current_ratio'} = $2;
	    $res->{'debt_equity'} = $4;
	    $res->{'total_cash'} = $6;
	}

	## Short Interest
	if ($content =~ s/.*?InterestAs\nof (.+?)Shares\nShort(.+?)Percent of Float(.+?)Shares Short\(Prior Month\)(.+?)Short Ratio(.+?) Daily Volume([\d\.KMB]+)//s) {
	    $res->{'short_interest_date'} = $1;
	    $res->{'short_interest'} = $2;
	    $res->{'short_percent'} = $3;
	    $res->{'short_previous_month'} = $4;
	    $res->{'short_ratio'} = $5;
	    $res->{'short_daily_volume'} = $6;
	}

	$self->_expand($res) if $self->{'expand_numbers'} || $self->{'expand_percent'} || $self->{'expand'};
	$res->{'success'} = 1;

	push(@res, $res);
    }

    return wantarray ? @res : \@res;

}

sub _expand {
    my ($self, $res) = @_;
    my (%factors, $key, $dollar, $factor, @number_keys, @percent_keys);

    %factors = ( 'K' => 1_000,
		 'M' => 1_000_000,
		 'B' => 1_000_000_000,
		 'T' => 1_000_000_000_000       ## for when we have the first trillion dollar company.
	       );

    @number_keys = qw(
		      daily_volume_10da
		      daily_volume_3ma
		      ebitda
		      income
		      market_capitalization
		      sales
		      shares_float
		      shares_outstanding
		      short_interest
		      short_daily_volume
		      short_previous_month
		      total_cash
		     );

    @percent_keys = qw(
		       52_week_change
		       52_week_change_sp500
		       dividend_yield
		       operating_margin
		       profit_margin
		       return_on_assets
		       return_on_equity
		       short_percent
		       );

    if ($self->{'expand_numbers'} || $self->{'expand'}) {
	for $key (@number_keys) {
	    $dollar = (($res->{$key} =~ s/^\$//) ? '$' : '');  ## save dollar sign'

	    if ($res->{$key} =~ s/(K|M|B|T)$//) {
		$res->{$key} *= $factors{$1};
	    }

	    if ($self->{'dollar_symbol'}) {
		$res->{$key} = $dollar . $res->{$key};
	    }
	}
    }

    if ($self->{'expand_percent'} || $self->{'expand'}) {
	for $key (@percent_keys) {
	    if ($res->{$key} =~ s/^([\+\-\d\.]+)%$/$1/) {
		$res->{$key} /= 100;
	    }
	}
    }
}


1;

__END__