File Coverage

blib/lib/Finance/OFX.pm

Criterion	Covered	Total	%
statement	12	75	16.0
branch	0	44	0.0
condition	0	3	0.0
subroutine	4	14	28.5
pod	8	10	80.0
total	24	146	16.4

# Filename: OFX.pm
# Serialize, Parse and Query using the Open Financial Exchange format
# http://www.ofx.net/
#
# Created January 30, 2008	Brandon Fosdick
#
# Copyright 2008 Brandon Fosdick  (BSD License)
#
# $Id: OFX.pm,v 1.2 2008/03/04 04:22:24 bfoz Exp $

package Finance::OFX;

use strict;
use warnings;

our $VERSION = '2';

use Finance::OFX::UserAgent;

use HTTP::Date;

sub new
{
    my ($this, %options) = @_;
    my $class = ref($this) || $this;
    my $self = {};
    bless $self, $class;

    # Assume any unprocessed options are meant for the UserAgent,
    #  which implies that this object will be used to generate and process
    #  requests instead of processing stored files
    $self->{ua} = Finance::OFX::UserAgent->new(%options) if scalar keys %options;

    return $self;
}

# --- Getters and Setters ---

sub institution
{
    my $s = shift;
    $s->{ua}->institution(@_);
}

sub response
{
    my $s = shift;
    $s->{ua}->{response};
}

sub user_id
{
    my $s = shift;
    $s->{ua}->user_id(@_);
}

sub user_pass
{
    my $s = shift;
    $s->{ua}->user_pass(@_);
}

# --- Public Methods ---

sub accounts
{
    my $s = shift;

    my $r = $s->{ua}->account_info;

    return -1 unless $r->is_success;
    return -2 if $r->signon_status_code;
    return undef unless $r->ofx->{signupmsgsrsv1}{acctinfotrnrs}{acctinfors}{acctinfo};

    my @accounts;
    for( @{$r->ofx->{signupmsgsrsv1}{acctinfotrnrs}{acctinfors}{acctinfo}} )
    {
	my %b = flatten($_);
	push @accounts, \%b;
    }
    return @accounts;
}

sub balance
{
    my ($s, $acct) = @_;
    return undef unless ref($acct) eq 'Finance::OFX::Account';

    # Use the FID from the given FI if none is set in the given Account
    $acct->fid($s->institution()->fid()) unless $acct->fid();

    my $r = $s->{ua}->statement($acct);
    return -1 unless $r->is_success;
    return -2 if $r->signon_status_code;
    return undef unless $r->ofx->{bankmsgsrsv1}{stmttrnrs};

    my $transaction = $r->ofx->{bankmsgsrsv1}{stmttrnrs};
    return "Statement request error: ".($transaction->{status}{message}) if transactionStatusCode($transaction);
    return "No statement info returned" unless exists $transaction->{stmtrs};

    return $transaction->{stmtrs};
}

sub transactions
{
    my ($s, $acct, $start, $end) = @_;
    return undef unless ref($acct) eq 'Finance::OFX::Account';

    # Use the FID from the given FI if none is set in the given Account
    $acct->fid($s->institution()->fid()) unless $acct->fid();

    my %options;
    $options{transactions} = 'Y';
    $options{start} = $start if $start;
    $options{end} = $end if $end;

    my $r = $s->{ua}->statement($acct, %options);
    return -1 unless $r->is_success;
    return -2 if $r->signon_status_code;
    my $ofx = $r->ofx;
    return undef unless $ofx->{bankmsgsrsv1}{stmttrnrs}{stmtrs};
    my $transaction = $ofx->{bankmsgsrsv1}{stmttrnrs};
    return "Statement request error: ".($transaction->{status}{message}) if transactionStatusCode($transaction);

    return $transaction->{stmtrs}{banktranlist};
}

sub transactionStatusCode
{
    my $tree = shift;
    return undef unless ref($tree) eq 'HASH';
    return $tree->{status}{code};
}

# --- Internal use only ---

# Blindly flatten a HoH
sub flatten
{
    my $tree = shift;
    return $tree unless ref($tree) eq 'HASH';
    my %a;
    for( keys %{$tree} )
    {
	$a{$_} = $tree->{$_}, next unless ref($tree->{$_}) eq 'HASH';
	my %b = flatten($tree->{$_});
	@a{keys %b} = values %b;
    }
    return %a;
}

1;

__END__