File Coverage

blib/lib/Finance/IIF.pm

Criterion	Covered	Total	%
statement	79	148	53.3
branch	33	80	41.2
condition	8	14	57.1
subroutine	15	17	88.2
pod	7	7	100.0
total	142	266	53.3

package Finance::IIF;

use 5.006;
use strict;
use warnings;
use Carp qw(carp croak);
use IO::File ();

our $VERSION = '0.21_02';
$VERSION = eval $VERSION;

sub new {
    my $class = shift;
    my %opt   = @_;
    my $self  = {};

    $self->{debug}           = $opt{debug}           || 0;
    $self->{autodetect}      = $opt{autodetect}      || 0;
    $self->{field_separator} = $opt{field_separator} || "\t";

    bless( $self, $class );

    if ( $opt{record_separator} ) {
        $self->record_separator( $opt{record_separator} );
    }

    if ( $opt{file} ) {
        $self->file( $opt{file} );
        $self->open;
    }
    return $self;
}

sub file {
    my $self = shift;
    if (@_) {
        my @file = ( ref( $_[0] ) eq "ARRAY" ? @{ shift @_ } : (), @_ );
        $self->{file} = [@file];
    }
    if ( $self->{file} ) {
        return wantarray ? @{ $self->{file} } : $self->{file}->[0];
    }
    else {
        return undef;
    }
}

sub record_separator {
    my $self = shift;
    if (@_) {
        $self->{record_separator} = $_[0] if ( $_[0] );
    }
    return $self->{record_separator} || $/;
}

sub _filehandle {
    my $self = shift;
    if (@_) {
        my @args = @_;
        $self->{_filehandle} = IO::File->new(@args)
          or croak("Failed to open file '$args[0]': $!");
        $self->{_linecount} = 0;
        $self->{_filehandle}->binmode();
    }
    if ( !$self->{_filehandle} ) {
        croak("No filehandle available");
    }
    return $self->{_filehandle};
}

sub open {
    my $self = shift;
    if (@_) {
        $self->file(@_);
    }
    if ( $self->file ) {
        $self->_filehandle( $self->file );
        if ( $self->{autodetect} ) {
            if ( $self->_filehandle->seek( -2, 2 ) ) {
                my $buffer = "";
                $self->_filehandle->read( $buffer, 2 );
                if ( $buffer eq "\015\012" ) {
                    $self->record_separator("\015\012");
                }
                elsif ( $buffer =~ /\012$/ ) {
                    $self->record_separator("\012");
                }
                elsif ( $buffer =~ /\015$/ ) {
                    $self->record_separator("\015");
                }
            }
        }
        $self->reset();
    }
    else {
        croak("No file specified");
    }
}

sub next {
    my $self = shift;
    my %object;
    my $continue = 1;
    if ( $self->_filehandle->eof ) {
        return undef;
    }
    my $line;
    while ( !$self->_filehandle->eof && $continue ) {

        # IIF files sometimes contain embedded record_separators so if
        # the previous line didn't have enough fields keep adding to it
        if ( $self->{_need_more} ) {
            if ( $self->{_need_more} > 8 ) {
                $self->_warning("Giving up trying to get next record");
                delete $self->{_need_more};
                $continue = 0;
            }
            else {
                $line .= $self->record_separator . $self->_getline;
            }
        }
        else {
            $line = $self->_getline;
            next if ( $line =~ /^\s*$/ );
        }

        my @data = $self->_parseline($line);

        if ( $self->{debug} > 1 ) {
            warn("_getline:   line($line)\n");
            warn( "_parseline: data[" . scalar(@data) . "](@data)\n" );
        }

        if ( $data[0] =~ /^!(.*)$/ ) {
            delete( $self->{headerfields} );
            shift(@data);
            $self->{header}       = $1;
            $self->{headerfields} = \@data;
        }
        elsif ( $data[0] eq $self->{header} ) {
            $object{header} = shift(@data);
            my $num_hdr = scalar( @{ $self->{headerfields} } );
            my $num_dat = scalar(@data);

            # have seen IIF timer data where last column (USEID) was
            # missing but QuickBooks imports the data without error
            if ( $num_dat < ( $num_hdr - 1 ) ) {
                $self->{_need_more}++;
            }
            elsif ( $num_dat > $num_hdr ) {
                $self->{_need_more} = $continue = 0;
                no warnings 'uninitialized';
                $self->_warning( "parse error: found $num_dat fields but"
                      . " expected $num_hdr." );
                warn(
                    "error info: [header,data] "
                      . join(
                        ' ',
                        map( "$_" . '['
                              . $self->{headerfields}->[$_] . ','
                              . $data[$_] . ']',
                            0 .. ( $num_hdr - 1 ) )
                      )
                );
            }
            else {
                $self->{_need_more} = $continue = 0;
                for ( my $i = 0 ; $i <= $#{ $self->{headerfields} } ; $i++ ) {
                    my $val = defined( $data[$i] ) ? $data[$i] : "";
                    $object{ $self->{headerfields}[$i] } = $val;
                }
            }
        }
        else {
            $self->_warning("unable to parse line '$_'");
        }
    }

    if ($continue) {
        return undef;
    }
    else {
        return \%object;
    }
}

sub _parseline {
    my $self = shift;
    my $line = shift;
    my $sep  = $self->{field_separator} || "\t";
    my @data;
    while ( defined $line ) {
        if ( $line =~ /^"(.*?)(?:[^\\]["])[$sep](.*)/s ) {
            warn("parse1: data($1) line($2)\n") if ( $self->{debug} > 2 );
            $line = $2;
            push( @data, $1 );
        }
        elsif ( $line =~ /^([^$sep]+)[$sep](.*)/s ) {
            warn("parse2: data($1) line($2)\n") if ( $self->{debug} > 2 );
            $line = $2;
            push( @data, $1 );
        }
        elsif ( $line =~ /^[$sep](.*)/s ) {
            warn("parse3: data() line($1)\n") if ( $self->{debug} > 2 );
            $line = $1;
            push( @data, "" );
        }
        elsif ( $line =~ /^"(.*?)(?:[^\\]["])$/s ) {
            warn("parse4: data($1) line()\n") if ( $self->{debug} > 2 );
            $line = undef;
            push( @data, $1 );
        }
        elsif ( $line =~ /^(.+)$/s ) {
            warn("parse5: data($1) line()\n") if ( $self->{debug} > 2 );
            $line = undef;
            push( @data, $1 );
        }
        else {
            warn("parse6: data() line($line)\n") if ( $self->{debug} > 2 );
            $line = undef;
            push( @data, "" );
        }
    }
    return @data;
}

sub _getline {
    my $self = shift;
    local $/ = $self->record_separator;
    my $line = $self->_filehandle->getline;
    $self->{_linecount}++;
    chomp($line);
    return $line;
}

sub _warning {
    my $self    = shift;
    my $message = shift;
    carp(   $message
          . " in file '"
          . $self->file
          . "' line "
          . $self->{_linecount} );
}

sub reset {
    my $self = shift;
    $self->_filehandle->seek( 0, 0 );
}

sub close {
    my $self = shift;
    $self->_filehandle->close;
}

1;

__END__