File Coverage

blib/lib/Finance/Currency/Convert/SCSB.pm

Criterion	Covered	Total	%
statement	23	43	53.4
branch	5	16	31.2
condition			n/a
subroutine	6	7	85.7
pod	2	2	100.0
total	36	68	52.9

package Finance::Currency::Convert::SCSB;

use strict;
use warnings;

our $VERSION = v0.1.1;

use Exporter 'import';
our @EXPORT_OK = qw(get_currencies convert_currency);

use Mojo::UserAgent;

sub get_currencies {
    my ($error, $result);

    my $dom;
    eval {
        $dom = _fetch_currency_exchange_web_page();
    } or do {
        $error = $@;
    };
    return ($error, undef) if defined $error;

    my @col_names = qw(zh_currency_name en_currency_name buy_at sell_at);
    my @cols = (
        $dom->find("td.txt09 > span")->map('all_text')->to_array(),
        $dom->find("td.txt09 + td > span")->map('all_text')->to_array(),
        $dom->find("td.txt09 + td + td.txt101 > span")->map('all_text')->to_array(),
        $dom->find("td.txt09 + td + td.txt101 + td.txt101 > span")->map('all_text')->to_array(),
    );

    my @rows = ();
    for my $i (0..$#{$cols[0]}) {
        my $currency = $cols[1][$i] =~ s/ CASH//r;
        push @rows, {
            currency         => $currency,
            zh_currency_name => $cols[0][$i],
            en_currency_name => $cols[1][$i],
            buy_at           => $cols[2][$i],
            sell_at          => $cols[3][$i],
        }
    }

    return (undef, \@rows);
}

sub convert_currency {
    my ($amount, $from_currency, $to_currency) = @_;
    return ("The convertion target must be 'TWD'. Cannot proceed with '$to_currency'", undef) unless $to_currency eq 'TWD';

    my $dom;
    my ($error, $result) = get_currencies();
    return ($error, undef) if defined $error;

    my $rate;
    for (@$result) {
        next if $_->{en_currency_name} =~ /CASH/;
        if ($_->{currency} eq $from_currency) {
            $rate = $_;
            last;
        }
    }
    return ("Unknown currency: $from_currency", undef) unless $rate;

    return (undef, $amount * $rate->{buy_at});
}

sub _fetch_currency_exchange_web_page {
    my $ua = Mojo::UserAgent->new;
    my $result = $ua->get('https://ibank.scsb.com.tw/netbank.portal?_nfpb=true&_pageLabel=page_other12&_nfls=false')->result;
    die $result->message if $result->is_error;
    return $result->dom;
}

1;

__END__