File Coverage

blib/lib/Finance/Bank/AllianceAndLeicester.pm

Criterion	Covered	Total	%
statement	12	67	17.9
branch	0	32	0.0
condition	0	3	0.0
subroutine	4	5	80.0
pod	1	1	100.0
total	17	108	15.7

package Finance::Bank::AllianceAndLeicester;

use strict;
use Carp;
use HTML::TokeParser;
use WWW::Mechanize;

our $VERSION = '1.03';

sub check_balance {

  # Get the inputs, and perform sanity checking.
  my ($class, %opts) = @_;
  croak 'Must provide a customer ID' unless exists $opts{customerid};
  croak 'Must provide memorable information' unless exists $opts{memorable};
  croak 'Must provide a unique phrase' unless exists $opts{phrase};
  croak 'Must provide a PIN code' unless exists $opts{pin};
  croak 'Customer ID should be 8 digits' unless $opts{customerid} =~ /^\d{8}$/;
  croak 'PIN code should be 5 digits' unless $opts{pin} =~ /^\d{5}$/;

  # Initialise the output array.
  my @accounts;

  # Submit the customer ID.
  my $agent = WWW::Mechanize->new();
  $agent->get('https://www.mybank.alliance-leicester.co.uk/index.asp');
  $agent->submit_form(fields    => {txtCustomerID => $opts{customerid}},
                      form_name => 'login');
  croak 'Login failed' unless $agent->success();

  # Submit the memorable information, if necessary.
  if ($agent->form_name('frmChangePIN')) {
    # We've got an extra step to perform.
    $agent->submit_form(fields    => {txtMemDetail => $opts{memorable}},
                        form_name => 'frmChangePIN');
    croak 'Failed to submit memorable data' unless $agent->success();
  }

  # Check we have got the correct unique phrase.
  my $content = $agent->content;
  my $stream = HTML::TokeParser->new(\$content) or die $!;
  for (my $a=0; $a < 5; $a++) {
    $stream->get_tag('span');
  }
  my $phrase = $stream->get_trimmed_text('/span');

  croak 'Unique phrase mismatch' unless (lc($phrase) eq lc($opts{phrase}));

  # Submit the PIN number.
  $agent->submit_form(fields    => {txtCustomerPIN => $opts{pin}},
                      form_name => 'frmPM4point1');
  croak 'Failed to submit PIN' unless $agent->success();

  # Check for login errors.
  $content = $agent->content;
  $stream = HTML::TokeParser->new(\$content) or die $!;
  while (my $token = $stream->get_tag('div')) {
    if ($token->[1]{'id'} && $token->[1]{'id'} eq 'error') {
      my $error = $stream->get_trimmed_text('/div');
      croak "Error during login: $error\n";
      last; # This is just silly.
    }
  }

  # Save this data to parse later.
  $content = $agent->{content};

  # We have the data we need, so let's log out.
  $agent->get('https://www.mybank.alliance-leicester.co.uk/' .
              'login/calls/logout.asp');

  # Begin parsing the HTML.
  $stream = HTML::TokeParser->new(\$content) or die $!;
  $stream->get_tag('tr');

  while (my $token = $stream->get_tag('tr')) {

    my($balance, $name, $overdraft, $account, $available_balance);

    # Get the account name and number.
    $token = $stream->get_tag('td');
    $name = $stream->get_trimmed_text('/td');
    $name =~ s/\s(\d+)$//;
    $account = $1;

    # Get the balance.
    $stream->get_tag('td');
    $balance = $stream->get_trimmed_text('/td');

    # Get the overdraft limit.
    $stream->get_tag('td');
    $overdraft = $stream->get_trimmed_text('/td');

    # Fix up the overdraft amount to zero, if there is no overdraft available.
    $overdraft = 0 if ($overdraft eq 'n/a');

    # Get the available balance.
    $stream->get_tag('td');
    $available_balance = $stream->get_trimmed_text('/td');

    # Strip pounds signs from balances.
    $balance   =~ s/^\x{00A3}//;
    $overdraft =~ s/^\x{00A3}//;
    $available_balance =~ s/^\x{00A3}//;

    # Strip Comma ',' from balances.
    $balance   =~ s/\,//g;
    $overdraft =~ s/\,//g;
    $available_balance =~ s/\,//g;

    # Add to list of accounts to return.
    push(@accounts, {balance           => $balance,
                     name              => $name,
                     overdraft         => $overdraft,
                     account           => $account,
                     available_balance => $available_balance});
  }

  return @accounts;
}

1;

__END__