File Coverage

blib/lib/Finance/AMEX/Transaction.pm

Criterion	Covered	Total	%
statement	56	58	96.5
branch	9	14	64.2
condition	5	7	71.4
subroutine	15	16	93.7
pod	7	7	100.0
total	92	102	90.2

package Finance::AMEX::Transaction 0.005;

use strict;
use warnings;

# ABSTRACT: Parse AMEX transaction files: EPRAW, EPPRC, EPTRN, CBNOT, GRRCN

use Finance::AMEX::Transaction::CBNOT;
use Finance::AMEX::Transaction::EPRAW;
use Finance::AMEX::Transaction::EPPRC;
use Finance::AMEX::Transaction::EPTRN;
use Finance::AMEX::Transaction::GRRCN;

sub new {
  my ($class, %props) = @_;

  my $self = bless {
    _file_type    => undef,
    _file_format  => undef,
    _file_version => undef,
    _parser       => undef,
  }, $class;

  my $type_map = {
    EPRAW => 'Finance::AMEX::Transaction::EPRAW',
    EPPRC => 'Finance::AMEX::Transaction::EPPRC',
    EPTRN => 'Finance::AMEX::Transaction::EPTRN',
    CBNOT => 'Finance::AMEX::Transaction::CBNOT',
    GRRCN => 'Finance::AMEX::Transaction::GRRCN',
  };

  $self->{_file_type}    = $props{file_type};
  $self->{_file_format}  = $props{file_format}  || 'UNKNOWN';
  $self->{_file_version} = $props{file_version} || 'UNKNOWN';

  if ($self->file_type and exists $type_map->{$self->file_type}) {
    $self->{_parser} = $type_map->{$self->file_type}->new(
      file_format  => $self->file_format,
      file_version => $self->file_version,
    );
  }

  return $self;
}

sub file_type {
  my ($self) = @_;

  return $self->{_file_type};
}

sub file_format {
  my ($self) = @_;

  return $self->{_file_format};
}

sub file_version {
  my ($self) = @_;

  return $self->{_file_version};
}

sub parser {
  my ($self) = @_;

  return $self->{_parser};
}

sub getline {
  my ($self, $fh) = @_;

  my $line = <$fh>;
  return $self->parse_line($line);
}

sub parse_line {
  my ($self, $line) = @_;

  my $ret = $self->{_parser}->parse_line($line);

  $self->_set_file_format;
  $self->_set_file_version;

  return $ret;
}

sub _set_file_format {
  my ($self) = @_;

  return if not $self->file_format eq 'UNKNOWN';
  return if $self->file_format eq $self->{_parser}->file_format;
  return if $self->{_parser}->file_format eq 'UNKNOWN';

  $self->{_file_format} = $self->{_parser}->file_format;

  return $self->file_format;
}

sub _set_file_version {
  my ($self) = @_;

  return if not $self->file_version eq 'UNKNOWN';
  return if $self->file_version eq $self->{_parser}->file_version;
  return if $self->{_parser}->file_version eq 'UNKNOWN';

  $self->{_file_version} = $self->{_parser}->file_version;

  return $self->file_version;
}

1;

__END__