File Coverage

blib/lib/Finance/AMEX/Transaction/GRRCN/Base.pm

Criterion	Covered	Total	%
statement	39	49	79.5
branch	6	14	42.8
condition	2	5	40.0
subroutine	9	10	90.0
pod	5	5	100.0
total	61	83	73.4

package Finance::AMEX::Transaction::GRRCN::Base 0.005;

use strict;
use warnings;

use Text::CSV;
use Carp 'croak';

# ABSTRACT: Parse AMEX Global Reconciliation (GRRCN) Base methods

sub new {
  my ($class, %props) = @_;
  my $self = bless {
    _line         => $props{line},
    _file_format  => $props{file_format},
    _fields       => undef,
    _file_version => $props{file_version} || 1.01,
  }, $class;

  my $map = $self->field_map;

  my $column_number = 0;
  my $numbered      = {};

  foreach my $column (@{$map}) {
    my ($field) = keys %{$column};
    $numbered->{$field} = $column_number++;
  }

  $self->{_fields} = $numbered;

  return $self;
}

sub line {
  my ($self) = @_;
  return $self->{_line};
}

sub file_format {
  my ($self) = @_;
  return $self->{_file_format};
}

sub fields {
  my ($self) = @_;
  return $self->{_fields};
}

sub file_version {
  my ($self) = @_;
  return $self->{_file_version};
}

sub _get_column {
  my ($self, $field) = @_;

  # this will happen if we're trying to get a field that does not
  # exist in the version of the file we are parsing
  return if not exists $self->fields->{$field};

  if ($self->file_format eq 'CSV' or $self->file_format eq 'TSV') {

    # Text::CSV does not like blank space at the end of the line
    $self->{_line} =~ s{\s+\z}{}xsm;
    my $index = $self->fields->{$field};

    my $csv = Text::CSV->new({
      binary      => 1,
      quote_char  => '"',
      escape_char => "\\",
    })
      or croak 'Cannot use CSV: ' . Text::CSV->error_diag();

    if ($self->file_format eq 'TSV') {
      $csv->sep_char("\t");
    }

    if (my $status = $csv->parse($self->{_line})) {
      return ($csv->fields)[$index];
    }

  } elsif ($self->file_format eq 'FIXED') {

    my $column_number = $self->fields->{$field};

    my $map = $self->field_map->{$column_number}->{$field};

    # if the line is not long enough to handle the start of the field,
    # it is an optional field that we don't have
    if (length($self->{_line}) < $map->[0]) {
      return '';
    }

    my $ret = substr($self->{_line}, $map->[0] - 1, $map->[1]);
    $ret =~ s{\s+\z}{}xsm;
    return $ret;
  }
}

1;

__END__