File Coverage

blib/lib/Finance/AMEX/Transaction/EPTRN.pm

Criterion	Covered	Total	%
statement	54	56	96.4
branch	7	10	70.0
condition	1	3	33.3
subroutine	16	16	100.0
pod	5	5	100.0
total	83	90	92.2

package Finance::AMEX::Transaction::EPTRN 0.005;

use strict;
use warnings;

use Finance::AMEX::Transaction::EPTRN::Header;
use Finance::AMEX::Transaction::EPTRN::Summary;
use Finance::AMEX::Transaction::EPTRN::Detail::ChargeSummary;
use Finance::AMEX::Transaction::EPTRN::Detail::RecordSummary;
use Finance::AMEX::Transaction::EPTRN::Detail::Chargeback;
use Finance::AMEX::Transaction::EPTRN::Detail::Adjustment;
use Finance::AMEX::Transaction::EPTRN::Detail::Other;
use Finance::AMEX::Transaction::EPTRN::Trailer;
use Finance::AMEX::Transaction::EPTRN::Unknown;

# ABSTRACT: Parse AMEX Transaction/Invoice Level Reconciliation (EPTRN)

sub new {
  my ($class, %props) = @_;

  my $type_map = {
    HEADER            => 'Finance::AMEX::Transaction::EPTRN::Header',
    SUMMARY           => 'Finance::AMEX::Transaction::EPTRN::Summary',
    SOC_DETAIL        => 'Finance::AMEX::Transaction::EPTRN::Detail::ChargeSummary',
    ROC_DETAIL        => 'Finance::AMEX::Transaction::EPTRN::Detail::RecordSummary',
    CHARGEBACK_DETAIL => 'Finance::AMEX::Transaction::EPTRN::Detail::Chargeback',
    ADJUSTMENT_DETAIL => 'Finance::AMEX::Transaction::EPTRN::Detail::Adjustment',
    OTHER_DETAIL      => 'Finance::AMEX::Transaction::EPTRN::Detail::Other',
    TRAILER           => 'Finance::AMEX::Transaction::EPTRN::Trailer',
  };

  my $self = bless {_type_map => $type_map}, $class;

  return $self;
}

sub file_format  {return 'N/A'}
sub file_version {return 'N/A'}

sub line_indicator {
  my ($self, $line) = @_;

  return if not defined $line;

  my $header_trailer_indicator = substr($line, 0, 5);

  my $indicator_map = {
    DFHDR => 'HEADER',
    DFTRL => 'TRAILER',
  };

  if (exists $indicator_map->{$header_trailer_indicator}) {
    return $indicator_map->{$header_trailer_indicator};
  }

  # if it is not a header or trailer, we need to look deeper
  my $summary_detail_indicator = join('-', substr($line, 42, 1), substr($line, 43, 2));

  my $summary_map = {
    '1-00' => 'SUMMARY',
    '2-10' => 'SOC_DETAIL',
    '3-11' => 'ROC_DETAIL',
    '2-20' => 'CHARGEBACK_DETAIL',
    '2-30' => 'ADJUSTMENT_DETAIL',
    '2-40' => 'OTHER_DETAIL',
    '2-41' => 'OTHER_DETAIL',
    '2-50' => 'OTHER_DETAIL',
  };

  if (exists $summary_map->{$summary_detail_indicator}) {
    return $summary_map->{$summary_detail_indicator};
  }

  # we don't know what it is!
  return;
}

sub parse_line {
  my ($self, $line) = @_;

  return if not defined $line;

  my $indicator = $self->line_indicator($line);

  if ($indicator and exists $self->{_type_map}->{$indicator}) {
    return $self->{_type_map}->{$indicator}->new(line => $line);
  }

  return Finance::AMEX::Transaction::EPTRN::Unknown->new(line => $line);
}

1;

__END__