File Coverage

blib/lib/File/chdir/WalkDir.pm

Criterion	Covered	Total	%
statement	37	46	80.4
branch	17	26	65.3
condition	1	2	50.0
subroutine	6	6	100.0
pod	1	1	100.0
total	62	81	76.5

package File::chdir::WalkDir;
{
  $File::chdir::WalkDir::VERSION = '0.040';
}

use strict;
use warnings;

use parent 'Exporter';
our @EXPORT = ( qw/walkdir/ );

use File::Spec::Functions 'no_upwards';
use File::chdir;

sub walkdir {
  my $opts = ( ref $_[-1] eq 'HASH' ) ? pop : {};

  my ($dir, $code_ref, @excluded_patterns) = @_;
  #old api support
  if (ref $opts->{'exclude'} eq 'Regexp') {
    push @excluded_patterns, $opts->{'exclude'};
  }
  push @{ $opts->{'exclude'} }, @excluded_patterns if @excluded_patterns;

  local $CWD = $dir;
  opendir( my $dh, $CWD);
  #print "In: $CWD\n";

  #holder for files/dirs that will be acted on after full dir is read,
  #use if worried about confusing readdir, say by renaming files
  my @deferred;

  FILE: while ( my $entry = readdir $dh ) {

    # next if the $entry refers to a '.' or '..' like construct
    next unless no_upwards( $entry );

    my $include = $opts->{'include'} || [];
    if (@$include) {
      my $allow = 0;

      foreach my $pattern (@$include) {
        if ($entry =~ $pattern) {
          $allow = 1;
          last;
        }
      }

      next unless $allow;
    }

    foreach my $pattern (@{ $opts->{'exclude'} || [] }) {
      next FILE if ($entry =~ $pattern);
    }

    if (-d $entry) {
      next if (-l $entry); # skip linked directories
      walkdir($entry, $code_ref, $opts);

      #all directory actions are deferred
      push @deferred, $entry if $opts->{'act_on_directories'};
    } else {
      if ($opts->{'defer'}) {
        push @deferred, $entry;
      } else {
        $code_ref->($entry, $CWD);
      }
    }

  }

  #process files/dirs that were deferred
  foreach my $entry (@deferred) {
    $code_ref->($entry, $CWD);
  }

}

1;

__END__