File Coverage

blib/lib/File/VirusScan/Engine/Command/NAI/Uvscan.pm

Criterion	Covered	Total	%
statement	22	66	33.3
branch	0	30	0.0
condition	0	3	0.0
subroutine	8	9	88.8
pod	1	2	50.0
total	31	110	28.1

package File::VirusScan::Engine::Command::NAI::Uvscan;
use strict;
use warnings;
use Carp;

use File::VirusScan::Engine::Command;
use vars qw( @ISA );
@ISA = qw( File::VirusScan::Engine::Command );

use Cwd 'abs_path';

use File::VirusScan::Result;

sub default_arguments
{
	return [ qw( --mime --noboot --secure --allole ) ];
}

sub scan
{
	my ($self, $path) = @_;

        my $abs = abs_path($path);
        if ($abs && $abs ne $path) {
                $path = $abs;
        }

	my ($exitcode, $scan_response) = eval { $self->_run_commandline_scanner(join(' ', $self->{command}, @{ $self->{args} }, $path, '2>&1'), qr/Found/,); };

	if($@) {
		return File::VirusScan::Result->error($@);
	}

	if(0 == $exitcode) {
		return File::VirusScan::Result->clean();
	}

	if(2 == $exitcode) {
		return File::VirusScan::Result->error('Driver integrity check failed');
	}

	if(6 == $exitcode) {

		# "A general problem occurred" -- idiot Windoze
		# programmers... nothing else to do but pass it on
		return File::VirusScan::Result->error('General problem occurred');
	}

	if(8 == $exitcode) {
		return File::VirusScan::Result->error('Could not find a driver');
	}

	if(12 == $exitcode) {
		return File::VirusScan::Result->error('Scanner tried to clean file, but failed');
	}

	if(13 == $exitcode) {

		# Finally, the virus-hit case
		#
		# TODO: what if more than one virus found?
		# TODO: can/should we capture infected filenames?

		# Sigh... stupid NAI can't have a standard message.  Go
		# through hoops to get virus name.
		$scan_response =~ s/ !+//;
		$scan_response =~ s/!+//;

		my $virus_name = '';

		for ($scan_response) {
			m/Found: EICAR test file/i && do {
				$virus_name = 'EICAR-Test';
				last;
			};
			m/^\s+Found the (\S+) .*virus/i && do {
				$virus_name = $1;
				last;
			};
			m/Found the (.*) trojan/i && do {
				$virus_name = $1;
				last;
			};
			m/Found .* or variant (.*)/i && do {
				$virus_name = $1;
				last;
			};
		}

		if($virus_name eq '') {
			$virus_name = 'unknown-NAI-virus';
		}

		return File::VirusScan::Result->virus($virus_name);
	}

	if(19 == $exitcode) {
		return File::VirusScan::Result->error('Self-check failed');
	}

	if(102 == $exitcode) {
		return File::VirusScan::Result->error('User quit using --exit-on-error');
	}

	return File::VirusScan::Result->error("Unknown return code from uvscan: $exitcode");
}

1;
__END__