File Coverage

blib/lib/File/VirusScan/Engine/Command/FPROT/Fpscan.pm

Criterion	Covered	Total	%
statement	22	52	42.3
branch	0	22	0.0
condition	0	5	0.0
subroutine	8	9	88.8
pod	1	2	50.0
total	31	90	34.4

package File::VirusScan::Engine::Command::FPROT::Fpscan;
use strict;
use warnings;
use Carp;

use File::VirusScan::Engine::Command;
use vars qw( @ISA );
@ISA = qw( File::VirusScan::Engine::Command );

use Cwd 'abs_path';

use File::VirusScan::Result;

sub default_arguments
{
	return [ qw( --report --archive=5  --scanlevel=4 --heurlevel=3 ) ];
}

sub scan
{
	my ($self, $path) = @_;

        my $abs = abs_path($path);
        if ($abs && $abs ne $path) {
                $path = $abs;
        }

	my ($exitcode, $scan_response) = eval { $self->_run_commandline_scanner(join(' ', $self->{command}, @{ $self->{args} }, $path, '2>&1')); };

	if($@) {
		return File::VirusScan::Result->error($@);
	}

	if(0 == $exitcode) {
		return File::VirusScan::Result->clean();
	}

	# bit 1 (1)   ==> At least one virus-infected object was found (and
	#                 remains).
	if( $exitcode & 0b1 ){
		my ($virus_name) = $scan_response =~  m/^\[Found\s+[^\]]*\]\s+<([^ \t\(>]*)/m;
		$virus_name ||= 'unknown-FPSCAN-virus';
		return File::VirusScan::Result->virus($virus_name);
	}

	# bit 2 (2)   ==> At least one suspicious (heuristic match) object
	#                 was found (and remains).
	if ($exitcode & 0b10) {
		return File::VirusScan::Result->virus('FPSCAN-suspicious');
	}

	# bit 3 (4)   ==> Interrupted by user (SIGINT, SIGBREAK).
	if ($exitcode & 0b100) {
		return File::VirusScan::Result->error('Interrupted by user');
	}

	# bit 4 (8)   ==> Scan restriction caused scan to skip files
	#                 (maxdepth directories, maxdepth archives,
	#                 exclusion list, etc).

	if ($exitcode & 0b1000) {
		return File::VirusScan::Result->error('Scanning restrictions triggered abort due to skipped files');
	}

	# bit 5 (16)  ==> Platform error (out of memory, real I/O errors,
	#                 insufficient file permission etc.)

	if ($exitcode & 0b10000) {
		return File::VirusScan::Result->error('Platform error (out of memory, I/O errors, etc)');
	}

	# bit 6 (32)  ==> Internal engine error (whatever the engine fails
	#                 at)
	if ($exitcode & 0b100000) {
		return File::VirusScan::Result->error('Internal virus engine error');
	}

	# bit 7 (64)  ==> At least one object was not scanned (encrypted
	#                 file, unsupported/unknown compression method,
	#                 corrupted or invalid file).
	if ($exitcode & 0b1000000) {
		return File::VirusScan::Result->error('At least one object not scannable');
	}

	# bit 8 (128) ==> At least one object was disinfected (clean now).
	# Should not happen as we aren't requesting disinfection ( at least
	# in this version).
	if ($exitcode & 0b10000000) {
		return File::VirusScan::Result->virus('Scanner claims to have cleaned a virus, but cannot in this mode');
	}

	return File::VirusScan::Result->error("Unknown return code: $exitcode");
}

1;
__END__