File Coverage

blib/lib/File/VirusScan/Engine/Daemon/Symantec/CSS.pm

Criterion	Covered	Total	%
statement	36	124	29.0
branch	4	46	8.7
condition	2	4	50.0
subroutine	11	15	73.3
pod	2	2	100.0
total	55	191	28.8

package File::VirusScan::Engine::Daemon::Symantec::CSS;
use strict;
use warnings;
use Carp;

use File::VirusScan::Engine::Daemon;
use vars qw( @ISA );
@ISA = qw( File::VirusScan::Engine::Daemon );

use IO::Socket::INET;
use Cwd 'abs_path';

use File::VirusScan::Result;

sub new
{
	my ($class, $conf) = @_;

	if(!$conf->{host}) {
		croak "Must supply a 'host' config value for $class";
	}

	my $self = {
		host     => $conf->{host},
		port     => $conf->{port} || 7777,
		is_local => $conf->{is_local} || 1,
	};

	return bless $self, $class;
}

sub _get_socket
{
	my ($self) = @_;

	my $sock = IO::Socket::INET->new(
		PeerAddr => $self->{host},
		PeerPort => $self->{port},
	);
	if(!defined $sock) {
		croak "Error: Could not connect to CarrierScan Server on $self->{host}, port $self->{port}: $!";
	}

	# First reply line should be 220 code
	my $line = _read_line($sock);
	unless ($line =~ /^220/) {
		croak "Error: Unexpected reply $line from CarrierScan Server";
	}

	# Next line must be version
	$line = _read_line($sock);
	unless ($line eq '2') {
		croak "Error: Unexpected version $line from CarrierScan Server";
	}

	# OK, probably fine to use this sock
	return $sock;
}

sub scan
{
	my ($self, $path) = @_;

	if(abs_path($path) ne $path) {
		return File::VirusScan::Result->error("Path $path is not absolute");
	}

	my @files = eval { $self->list_files($path) };
	if($@) {
		return File::VirusScan::Result->error($@);
	}

	foreach my $file_path (@files) {
		my $result
		  = $self->{is_local}
		  ? $self->_scan_local($file_path)
		  : $self->_scan_remote($file_path);
		if(!$result->is_clean()) {
			return $result;
		}
	}
}

sub _scan_local
{
	my ($self, $path) = @_;

	my $sock = eval { $self->_get_socket };
	if($@) {
		return File::VirusScan::Result->error($@);
	}

	if(!$sock->print("Version2\nAVSCANLOCAL\n$path\n")) {
		my $err = $!;
		$sock->close;
		return File::VirusScan::Result->error("Could not write to socket: $err");
	}

	if(!$sock->flush) {
		my $err = $!;
		$sock->close;
		return File::VirusScan::Result->error("Error flushing socket: $err");
	}

	my $result = $self->_parse_server_response($sock);
	$sock->close;
	return $result;
}

sub _scan_remote
{
	my ($self, $path) = @_;

	my $size = (stat($path))[7];
	unless (defined($size)) {
		return File::VirusScan::Result->error("Cannot stat $path: $!");
	}

	my $sock = eval { $self->_get_socket };
	if($@) {
		return File::VirusScan::Result->error($@);
	}

	if(!$sock->print("Version2\nAVSCAN\n$path\n$size\n")) {
		my $err = $!;
		$sock->close;
		return File::VirusScan::Result->error("Could not write to socket: $err");
	}

	my $fh = IO::File->new("<$path");
	if(!$fh) {
		return File::VirusScan::Result->error("Cannot open $path: $!");
	}

	# Write file to socket
	while ($size > 0) {
		my $chunksize
		  = ($size < 8192)
		  ? $size
		  : 8192;

		my $chunk;
		my $nread = $fh->read($chunk, $chunksize);
		unless (defined $nread) {
			my $err = $!;
			$sock->close;
			return File::VirusScan::Result->error("Error reading $path: $err");
		}

		last if($nread == 0);

		if(!$sock->print($chunk)) {
			my $err = $!;
			$sock->close;
			return File::VirusScan::Result->error("Error writing to socket: $err");
		}

		$size -= $nread;
	}

	if($size > 0) {
		my $err = $!;
		$sock->close;
		return File::VirusScan::Result->error("Error reading $path: $err");
	}

	if(!$sock->flush) {
		my $err = $!;
		$sock->close;
		return File::VirusScan::Result->error("Error flushing socket: $err");
	}

	my $result = $self->_parse_server_response($sock);
	$sock->close;
	return $result;
}

sub _parse_server_response
{
	my ($self, $sock) = @_;

	# Get reply from server
	my $line = _read_line($sock);

	unless ($line =~ /^230/) {
		return File::VirusScan::Result->error("Unexpected response to AVSCAN or AVSCANLOCAL command: $line");
	}

	# Read infection status
	$line = _read_line($sock);
	if($line eq '0') {
		return File::VirusScan::Result->clean();
	}

	# Skip next four lines:
	# 	- definition date
	# 	- definition version
	# 	- infection count
	# 	- filename
	$line = _read_line($sock);
	$line = _read_line($sock);
	$line = _read_line($sock);
	$line = _read_line($sock);

	# Get virus name
	$line = _read_line($sock);

	return File::VirusScan::Result->virus($line);
}

sub _read_line
{
	my ($sock) = @_;

	chomp(my $line = $sock->getline);
	$line =~ s/\r//g;
	return $line;
}

1;
__END__