File Coverage

blib/lib/File/Util/Tempdir.pm

Criterion	Covered	Total	%
statement	28	35	80.0
branch	16	26	61.5
condition	7	9	77.7
subroutine	5	5	100.0
pod	2	2	100.0
total	58	77	75.3

package File::Util::Tempdir;

our $DATE = '2018-09-20'; # DATE
our $VERSION = '0.033'; # VERSION

use strict;
use warnings;

use Exporter qw(import);
our @EXPORT_OK = qw(get_tempdir get_user_tempdir);

sub get_tempdir {
    if ($^O eq 'MSWin32') {
        for (qw/TMP TEMP TMPDIR TEMPDIR/) {
            return $ENV{$_} if defined $ENV{$_};
        }
        for ("C:\\TMP", "C:\\TEMP") {
            return $_ if -d;
        }
    } else {
        for (qw/TMPDIR TEMPDIR TMP TEMP/) {
            return $ENV{$_} if defined $ENV{$_};
        }
        for ("/tmp", "/var/tmp") {
            return $_ if -d;
        }
    }
    die "Can't find any temporary directory";
}

sub get_user_tempdir {
    if ($^O eq 'MSWin32') {
        return get_tempdir();
    } else {
        my $dir = $ENV{XDG_RUNTIME_DIR} ?
            $ENV{XDG_RUNTIME_DIR} : get_tempdir();
        my @st = stat($dir);
        die "Can't stat tempdir '$dir': $!" unless @st;
        return $dir if $st[4] == $> && !($st[2] & 022);
        my $i = 0;
        while (1) {
            my $subdir = "$dir/$>" . ($i ? ".$i" : "");
            my @stsub = stat($subdir);
            my $is_dir = -d _;
            if (!@stsub) {
                mkdir $subdir, 0700 or die "Can't mkdir '$subdir': $!";
                return $subdir;
            } elsif ($is_dir && $stsub[4] == $> && !($stsub[2] & 022)) {
                return $subdir;
            } else {
                $i++;
            }
        }
    }
}

1;
# ABSTRACT: Cross-platform way to get system-wide & user private temporary directory

__END__