File Coverage

blib/lib/File/Slurper/Temp.pm

Criterion	Covered	Total	%
statement	35	37	94.5
branch	2	4	50.0
condition			n/a
subroutine	9	11	81.8
pod	4	4	100.0
total	50	56	89.2

package File::Slurper::Temp;

our $DATE = '2019-07-21'; # DATE
our $VERSION = '0.006'; # VERSION

use strict;
use warnings;

use Carp 'croak';
use File::Slurper ();
use File::Temp ();

use Exporter qw(import);
our @EXPORT_OK = qw(
                       write_text write_binary
                       write_text_to_tempfile write_binary_to_tempfile
               );

our $FILE_TEMP_TEMPLATE = "XXXXXXXXXX";
our $FILE_TEMP_DIR;

sub _tempfile {
    my $target_filename = shift;

    my @tfargs;
    push @tfargs, $FILE_TEMP_TEMPLATE;
    my $dir = $FILE_TEMP_DIR;
    unless (defined $dir) {
        require File::Spec;
        (undef, $dir, undef) = File::Spec->splitpath($target_filename);
    }
    push @tfargs, DIR => $dir;
    File::Temp::tempfile(@tfargs);
}

sub write_text {
    my $filename = shift;

    my ($tempfh, $tempname) = _tempfile($filename);
    File::Slurper::write_text($tempname, @_);
    rename $tempname, $filename
        or croak "Couldn't rename $tempname to $filename: $!";

    return;
}

sub write_binary {
    return write_text(@_[0,1], 'latin-1');
}

sub write_text_to_tempfile {
    my ($tempfh, $tempname) = File::Temp::tempfile();
    File::Slurper::write_text($tempname, @_);
    return $tempname;
}

sub write_binary_to_tempfile {
    return write_text_to_tempfile($_[0], 'latin-1');
}

1;
# ABSTRACT: File::Slurper + File::Temp

__END__