File Coverage

blib/lib/File/Object.pm

Criterion	Covered	Total	%
statement	132	132	100.0
branch	42	42	100.0
condition	17	17	100.0
subroutine	18	18	100.0
pod	9	9	100.0
total	218	218	100.0

package File::Object;

use strict;
use warnings;

use Class::Utils qw(set_params);
use Error::Pure qw(err);
use File::Spec::Functions qw(catdir catfile splitdir);
use FindBin qw($Bin $Script);

our $VERSION = 0.17;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Directory path.
	$self->{'dir'} = [];

	# File path.
	$self->{'file'} = undef;

	# Type of path.
	$self->{'type'} = 'dir';

	# Process parameters.
	set_params($self, @params);

	# Check to right 'type'.
	if (! $self->{'type'} || ($self->{'type'} ne 'file'
		&& $self->{'type'} ne 'dir')) {

		err 'Bad \'type\' parameter.';
	}

	# Check to dir.
	if (ref $self->{'dir'} ne 'ARRAY') {
		err '\'dir\' parameter must be a reference to array.';
	}

	# Check to file.
	if ($self->{'type'} eq 'file' && @{$self->{'dir'}}
		&& ! defined $self->{'file'}) {

		err 'Bad file constructor with undefined \'file\' parameter.';
	}

	# Remove undef dirs.
	if (@{$self->{'dir'}}) {
		my @dir = map { defined $_ ? $_ : () } @{$self->{'dir'}};
		$self->{'dir'} = \@dir;
	}

	# Update path.
	$self->_update_path;

	# Set values.
	$self->set;

	# Object.
	return $self;
}

# Add dir.
sub dir {
	my ($self, @dirs) = @_;

	foreach my $dir (@dirs) {
		if (defined $dir) {
			$self->_dir($dir);
		}
	}

	# Object.
	return $self;
}

# Add file.
sub file {
	my ($self, @file_path) = @_;

	my $file = pop @file_path;
	$self->dir(@file_path);
	$self->_file($file);

	return $self;
}


# Get dir.
sub get_dir {
	my ($self, $dir_num) = @_;

	$dir_num ||= 1;
	if ($self->{'type'} eq 'file') {
		$dir_num++;
	}

	return $self->{'path'}->[-$dir_num];
}

# Get file.
sub get_file {
	my $self = shift;

	if ($self->{'type'} eq 'file') {
		return $self->{'path'}->[-1];
	} else {
		return;
	}
}

# Reset to constructor values.
sub reset {
	my $self = shift;

	# Reset to setted values.
	$self->{'dir'} = $self->{'_set'}->{'dir'};
	$self->{'file'} = $self->{'_set'}->{'file'};
	$self->{'type'} = $self->{'_set'}->{'type'};

	# Update path.
	$self->_update_path;

	return $self;
}

# Serialize path.
sub s {
	my $self = shift;

	if ($self->{'type'} eq 'dir') {
		return catdir(@{$self->{'path'}});
	} else {
		return catfile(@{$self->{'path'}});
	}
}

# Set actual values to constructor values.
sub set {
	my $self = shift;

	my @path = @{$self->{'path'}};
	$self->{'_set'}->{'type'} = $self->{'type'};
	if ($self->{'type'} eq 'file') {
		$self->{'_set'}->{'file'} = pop @path;
		$self->{'_set'}->{'dir'} = \@path;
	} else {
		$self->{'_set'}->{'dir'} = \@path;
	}

	return $self;
}

# Go to parent directory.
sub up {
	my ($self, $up_num) = @_;

	# Check number and positive number.
	if (! $up_num || $up_num !~ m/^\d$/ms) {
		$up_num = 1;
	}

	# Process.
	foreach (1 .. $up_num) {
		if ($self->{'type'} eq 'file') {
			if (@{$self->{'path'}} > 2) {
				$self->{'type'} = 'dir';
				$self->{'file'} = undef;
				splice @{$self->{'path'}}, -2;
			} else {
				err 'Cannot go up.', 'PATH', $self->s;
			}
		} else {
			if (@{$self->{'path'}}) {
				pop @{$self->{'path'}};
			} else {
				err 'Cannot go up.', 'PATH', $self->s;
			}
		}
	}

	# Object.
	return $self;
}

# Add dir array.
sub _dir {
	my ($self, @dir) = @_;

	if ($self->{'type'} eq 'file') {
		$self->{'type'} = 'dir';
		$self->{'file'} = undef;
		pop @{$self->{'path'}};
	}
	push @{$self->{'path'}}, @dir;

	return;
}

# Add file array.
sub _file {
	my ($self, $file) = @_;

	if (! defined $file) {
		return;
	}
	if ($self->{'type'} eq 'file') {
		pop @{$self->{'path'}};
		push @{$self->{'path'}}, $file;
	} else {
		push @{$self->{'path'}}, $file;
		$self->{'type'} = 'file';
	}

	return;
}

# Update path.
sub _update_path {
	my $self = shift;

	if ($self->{'type'} eq 'file') {
		$self->{'path'} = [
			@{$self->{'dir'}},
			defined $self->{'file'} ? $self->{'file'} : (),
		];
		if (! @{$self->{'path'}}) {
			$self->{'path'} = [splitdir($Bin), $Script];
		}
	} else {
		$self->{'path'} = [@{$self->{'dir'}}];
		if (! @{$self->{'path'}}) {
			$self->{'path'} = [splitdir($Bin)];
		}
	}

	return;
}

1;

__END__