File Coverage

blib/lib/File/LibMagic/FFI.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package File::LibMagic::FFI;

use strict;
use warnings;
use 5.008001;
use FFI::Platypus;
use FFI::Platypus::Buffer ();
use FFI::CheckLib 0.06 ();
use constant {
  _MAGIC_NONE => 0x000000,
  _MAGIC_MIME => 0x000410, #MIME_TYPE | MIME_ENCODING,
};

# ABSTRACT: Determine MIME types of data or files using libmagic
our $VERSION = '0.04'; # VERSION


our $ffi = FFI::Platypus->new;
$ffi->lib(FFI::CheckLib::find_lib_or_die( lib => "magic" ));
$ffi->type(opaque => 'magic_t');

$ffi->attach( [magic_open   => '_open']   => ['int']                       => 'magic_t' );
$ffi->attach( [magic_load   => '_load']   => ['magic_t','string']          => 'int'     );
$ffi->attach( [magic_file   => '_file']   => ['magic_t','string']          => 'string'  );
$ffi->attach( [magic_buffer => '_buffer'] => ['magic_t','opaque','size_t'] => 'string'  );
$ffi->attach( [magic_close  => '_close']  => ['magic_t']                   => 'void'    );


sub new
{
  my($class, $magic_file) = @_;
  return bless { magic_file => $magic_file }, $class;
}

sub _mime_handle
{
  my($self) = @_;
  return $self->{mime_handle} ||= do {
    my $handle = _open(_MAGIC_MIME);
    _load($handle, $self->{magic_file});
    $handle;
  };
}

sub _describe_handle
{
  my($self) = @_;
  return $self->{describe_handle} ||= do {
    my $handle = _open(_MAGIC_NONE);
    _load($handle, $self->{magic_file});
    $handle;
  };
}

sub DESTROY
{
  my($self) = @_;
  _close($self->{magic_handle}) if defined $self->{magic_handle};
  _close($self->{mime_handle}) if defined $self->{mime_handle};
}


sub checktype_contents
{
  _buffer($_[0]->_mime_handle, FFI::Platypus::Buffer::scalar_to_buffer(ref $_[1] ? ${$_[1]} : $_[1]));
}


sub checktype_filename
{
  _file($_[0]->_mime_handle, $_[1]);
}


sub describe_contents
{
  _buffer($_[0]->_describe_handle, FFI::Platypus::Buffer::scalar_to_buffer(ref $_[1] ? ${$_[1]} : $_[1]));
}


sub describe_filename
{
  _file($_[0]->_describe_handle, $_[1]);
}


1;

__END__