File Coverage

blib/lib/File/Format/CRD/Reader.pm

Criterion	Covered	Total	%
statement	17	78	21.7
branch	0	16	0.0
condition	0	2	0.0
subroutine	6	16	37.5
pod	4	4	100.0
total	27	116	23.2

package File::Format::CRD::Reader;
$File::Format::CRD::Reader::VERSION = '0.2.2';
use warnings;
use strict;

use 5.008;

use Carp;

use Encode;

use Fcntl qw(SEEK_SET);



sub new
{
    my $class = shift;

    my $self = bless {}, $class;

    $self->_init(@_);

    return $self;
}

sub _read_from
{
    my ($self, $pos, $count) = @_;

    if (!seek($self->{_fh}, $pos, SEEK_SET))
    {
        Carp::confess("Cannot seek to $pos.");
    }

    my $buffer = "";
    if (read($self->{_fh}, $buffer, $count) != $count)
    {
        Carp::confess("Could not read $count bytes.");
    }

    return $buffer;
}

sub _read_short
{
    my $self = shift;
    my $pos = shift;

    my $buffer = $self->_read_from($pos, 2);

    return unpack("v", $buffer);
}

sub _read_long
{
    my $self = shift;
    my $pos = shift;

    return unpack("V", $self->_read_from($pos, 4));
}

sub _init
{
    my ($self, $args) = @_;

    my $filename = $args->{'filename'};

    open my $in, "<", $filename
        or Carp::confess "Could not open '$filename'";

    binmode ($in);

    $self->{_fh} = $in;

    my $magic = $self->_read_from(0, 3);

    if ($magic ne "MGC")
    {
        Carp::confess("Could not find magic number in file.");
    }

    my $n_cards = $self->_read_short(3);

    $self->{_num_cards} = $n_cards;

    $self->{_card_idx} = 0;

    return;
}


sub get_num_cards
{
    return shift->{_num_cards};
}

sub DESTROY
{
    my $self = shift;

    $self->finish();

    return;
}


sub finish
{
    my $self = shift;

    if (exists($self->{_fh}))
    {
        close($self->{_fh});

        delete($self->{_fh});
    }

    return;
}


sub get_next_card
{
    my $self = shift;
    my $args = shift || {};

    my $encoding = $args->{'encoding'};

    my $card_idx = $self->{_card_idx};

    if ($card_idx == $self->get_num_cards())
    {
        return;
    }

    my $loc = 11 + $card_idx * 52;

    my $textloc = $self->_read_long($loc);

    if (! ($textloc >= 57))
    {
        Carp::confess("textloc is too small");
    }

    my $transform = sub {
        my $text = shift;

        if (defined($encoding))
        {
            return decode($encoding, $text);
        }
        else
        {
            return $text;
        }
    };

    my $title = $self->_read_from($loc+5, 52-5);

    my $ret = { 'title' => $transform->($title) };

    my $textlen = $self->_read_short($textloc+2);

    my $text = $self->_read_from($textloc+4, $textlen);

    $ret->{'body'} = $transform->($text);
    ++($self->{_card_idx});

    return $ret;
}



1; # End of File::Format::CRD::Reader

__END__