File Coverage

blib/lib/File/Find/Parallel.pm

Criterion	Covered	Total	%
statement	48	49	97.9
branch	9	10	90.0
condition	3	5	60.0
subroutine	13	13	100.0
pod	7	7	100.0
total	80	84	95.2

package File::Find::Parallel;

use warnings;
use strict;
use Carp;
use File::Spec;

our $VERSION = '0.52';

sub new {
    my $class = shift;
    my $self = bless { dirs => [], }, ref $class || $class;
    $self->add_dirs( @_ );
    return $self;
}

sub set_dirs {
    my $self = shift;
    $self->{dirs} = [@_];
}

sub get_dirs {
    my $self = shift;
    return @{ $self->{dirs} };
}

sub add_dirs {
    my $self = shift;
    push @{ $self->{dirs} }, @_;
}

sub want_iterator {
    my $self = shift;
    my $threshold = shift || 1;

    my @dirs = $self->get_dirs;
    my @work = @dirs ? ( '.' ) : ();

    # Return an empty iterator if asked for more instances of an object
    # than we could ever have.
    return sub { return }
      if $threshold > @dirs;

    return sub {
        return unless @work;
        my $rel = File::Spec->canonpath( shift @work );
        my %got = ();
        for my $base ( @dirs ) {
            my $abs = File::Spec->catdir( $base, $rel );
            if ( -d $abs ) {
                if ( opendir my $dh, $abs ) {
                    $got{$_}++ for grep { $_ !~ /^[.][.]?$/ } readdir $dh;
                }
                else {
                    carp "Can't read $abs ($!)";
                }
            }
        }
        push @work, map { File::Spec->catdir( $rel, $_ ) }
          sort grep { $got{$_} >= $threshold } keys %got;
        return $rel;
    };
}

sub all_iterator {
    my $self = shift;
    return $self->want_iterator( scalar $self->get_dirs );
}

sub any_iterator {
    my $self = shift;
    return $self->want_iterator( 1 );
}

1;
__END__