File Coverage

blib/lib/File/Find/Object/Rule/VCS.pm

Criterion	Covered	Total	%
statement	41	48	85.4
branch	10	18	55.5
condition			n/a
subroutine	13	14	92.8
pod	0	5	0.0
total	64	85	75.2

package File::Find::Object::Rule::VCS;
$File::Find::Object::Rule::VCS::VERSION = '0.0.4';

use 5.008;

use strict;
use warnings;

use UNIVERSAL;
use Carp                  ();
use Text::Glob       0.08 ();
use File::Find::Object::Rule ();

use vars qw{@ISA @EXPORT};
use parent 'File::Find::Object::Rule';

my $FFOR = 'File::Find::Object::Rule';

# In some Windows SVN implementations, it uses _svn instead of
# .svn, so use both on Win32.
my @svn = ($^O eq 'MSWin32') ? ('.svn', '_svn') : ('.svn');

#####################################################################
# File::Find::Object::Rule Method Addition


sub File::Find::Object::Rule::ignore_vcs {
    my $find = $_[0]->_force_object;

    # Handle special cases
    unless ( @_ ) {
        # Logically combine all the ignores. This will be much
        # faster than just calling them all one after the other.
        return $find->or(
            $FFOR->name(@svn, '.bzr', '.git', 'CVS')->directory->prune->discard,
            $FFOR->name(qr/^\.\#/)->file->discard,
            $FFOR->new,
            );
    }
    unless ( defined $_[1] ) {
        Carp::croak("->ignore_vcs: No version control system name provided");
    }

        # As a convenience for higher-level APIs
        # we treat a defined null string as a nullop
    my $vcs = lc $_[1];
        return $find if $vcs eq '';

    # Hand off to the rules for each VCS
    return $find->ignore_cvs if $vcs eq 'cvs';
    return $find->ignore_svn if $vcs eq 'svn';
    return $find->ignore_svn if $vcs eq 'subversion';
    return $find->ignore_bzr if $vcs eq 'bzr';
    return $find->ignore_bzr if $vcs eq 'bazaar';
    return $find->ignore_git if $vcs eq 'git';
    Carp::croak("->ignore_vcs: '$vcs' is not supported");
}


sub File::Find::Object::Rule::ignore_cvs {
    my $find = $_[0]->_force_object;
    return $find->or(
        $FFOR->name('CVS')->directory->prune->discard,
        $FFOR->name(qr/^\.\#/)->file->discard,
        $FFOR->new,
        );
}


sub File::Find::Object::Rule::ignore_svn {
    my $find = $_[0]->_force_object;
    return $find->or(
        $FFOR->name(@svn)->directory->prune->discard,
        $FFOR->new,
        );
}


sub File::Find::Object::Rule::ignore_bzr {
    my $find = $_[0]->_force_object;
    return $find->or(
        $FFOR->name('.bzr')->directory->prune->discard,
        $FFOR->new,
        );
}


sub File::Find::Object::Rule::ignore_git {
    my $find = $_[0]->_force_object;
    return $find->or(
        $FFOR->name('.git')->directory->prune->discard,
        $FFOR->new,
        );
}

1;

__END__