File Coverage

blib/lib/File/Digest.pm

Criterion	Covered	Total	%
statement	54	62	87.1
branch	15	18	83.3
condition	2	6	33.3
subroutine	8	8	100.0
pod	2	2	100.0
total	81	96	84.3

package File::Digest;

our $DATE = '2019-09-12'; # DATE
our $VERSION = '0.009'; # VERSION

use 5.010001;
use strict;
use warnings;
use Log::ger;

use Exporter qw(import);
our @EXPORT_OK = qw(digest_files);

use Perinci::Object;

our %SPEC;

$SPEC{':package'} = {
    v => 1.1,
    summary => 'Calculate file checksum/digest (using various algorithms)',
};

my %arg_file = (
    file => {
        summary => 'Filename ("-" means stdin)',
        schema => ['filename*'],
        req => 1,
        pos => 0,
        cmdline_aliases => {f=>{}},
    },
);

my %arg_files = (
    files => {
        'x.name.is_plural' => 1,
        'x.name.singular' => 'file',
        summary => 'Array of filenames (filename "-" means stdin)',
        schema => ['array*', of=>'filename*'],
        req => 1,
        pos => 0,
        greedy => 1,
        cmdline_aliases => {f=>{}},
    },
);

my %arg_algorithm = (
    algorithm => {
        schema => ['str*', in=>[qw/crc32 md5 sha1 sha224 sha256 sha384 sha512 sha512224 sha512256 Digest/]],
        default => 'md5',
        cmdline_aliases => {a=>{}},
    },
    digest_args => {
        schema => ['array*', of=>'str*', 'x.perl.coerce_rules'=>['str_comma_sep']],
        cmdline_aliases => {A=>{}},
    },
);

$SPEC{digest_file} = {
    v => 1.1,
    summary => 'Calculate file checksum/digest (using various algorithms)',
    description => <<'_',

Return 400 status when algorithm is unknown/unsupported.

_
    args => {
        %arg_file,
        %arg_algorithm,
    },
};
sub digest_file {
    my %args = @_;

    my $file = $args{file};
    my $algo = $args{algorithm} // 'md5';

    my $fh;
    if ($file eq '-') {
        $fh = \*STDIN;
    } else {
        unless (-f $file) {
            log_warn("Can't open %s: no such file", $file);
            return [404, "No such file '$file'"];
        }
        open $fh, "<", $file or do {
            log_warn("Can't open %s: %s", $file, $!);
            return [500, "Can't open '$file': $!"];
        };
    }

    if ($algo eq 'md5') {
        require Digest::MD5;
        my $ctx = Digest::MD5->new;
        $ctx->addfile($fh);
        return [200, "OK", $ctx->hexdigest];
    } elsif ($algo =~ /\Asha(512224|512256|224|256|384|512|1)\z/) {
        require Digest::SHA;
        my $ctx = Digest::SHA->new($1);
        $ctx->addfile($fh);
        return [200, "OK", $ctx->hexdigest];
    } elsif ($algo eq 'crc32') {
        require Digest::CRC;
        my $ctx = Digest::CRC->new(type=>'crc32');
        $ctx->addfile($fh);
        return [200, "OK", $ctx->hexdigest];
    } elsif ($algo eq 'Digest') {
        require Digest;
        my $ctx = Digest->new(@{ $args{digest_args} // [] });
        $ctx->addfile($fh);
        return [200, "OK", $ctx->hexdigest];
    } else {
        return [400, "Invalid/unsupported algorithm '$algo'"];
    }
}

$SPEC{digest_files} = {
    v => 1.1,
    summary => 'Calculate file checksum/digest (using various algorithms)',
    description => <<'_',

Dies when algorithm is unsupported/unknown.

_
    args => {
        %arg_files,
        %arg_algorithm,
    },
};
sub digest_files {
    my %args = @_;

    my $files = $args{files};
    my $algo  = $args{algorithm} // 'md5';

    my $envres = envresmulti();
    my @res;

    for my $file (@$files) {
        my $itemres = digest_file(file => $file, algorithm=>$algo);
        die $itemres->[1] if $itemres->[0] == 400;
        $envres->add_result($itemres->[0], $itemres->[1], {item_id=>$file});
        push @res, {file=>$file, digest=>$itemres->[2]} if $itemres->[0] == 200;
    }

    $envres = $envres->as_struct;
    $envres->[2] = \@res;
    $envres->[3]{'table.fields'} = [qw/file digest/];
    $envres;
}

1;
# ABSTRACT: Calculate file checksum/digest (using various algorithms)

__END__