File Coverage

blib/lib/File/ChangeNotify.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	5	8	62.5
condition	1	3	33.3
subroutine	11	11	100.0
pod	2	2	100.0
total	59	64	92.1

package File::ChangeNotify;

use strict;
use warnings;
use namespace::autoclean;

our $VERSION = '0.30';

use Carp qw( confess );

# We load this up front to make sure that the prereq modules are installed.
use File::ChangeNotify::Watcher::Default;
use Module::Pluggable::Object;
use Module::Runtime qw( use_module );

# First version to support coerce => 1
use Moo 1.006 ();

sub instantiate_watcher {
    my $class = shift;

    my @usable = $class->usable_classes;
    return $usable[0]->new(@_) if @usable;

    return File::ChangeNotify::Watcher::Default->new(@_);
}

{
    my $finder = Module::Pluggable::Object->new(
        search_path => 'File::ChangeNotify::Watcher' );
    my $loaded;
    my @usable_classes;

    sub usable_classes {
        return @usable_classes if $loaded;
        @usable_classes = grep { _try_load($_) }
            sort grep { $_ ne 'File::ChangeNotify::Watcher::Default' }
            $finder->plugins;
        $loaded = 1;

        return @usable_classes;
    }
}

sub _try_load {
    my $module = shift;

    my $ok = eval { use_module($module) };
    my $e = $@;
    return $module if $ok;

    die $e
        if $e
        && $e !~ /Can\'t locate|did not return a true value/;
}

1;

# ABSTRACT: Watch for changes to files, cross-platform style

__END__